*         ,----,
*       ,/   .`|                                      ,----,   ,----..            ,--.
*     ,`   .'  :  ,---,                             .'   .`|  /   /   \         ,--.'|    ,---,.
*   ;    ;     /,--.' |                          .'   .'   ; /   .     :    ,--,:  : |  ,'  .' |
* .'___,/    ,' |  |  :                        ,---, '    .'.   /   ;.  \,`--.'`|  ' :,---.'   |
* |    :     |  :  :  :                        |   :     ./.   ;   /  ` ;|   :  :  | ||   |   .'
* ;    |.';  ;  :  |  |,--.   ,---.            ;   | .'  / ;   |  ; \ ; |:   |   \ | ::   :  |-,
* `----'  |  |  |  :  '   |  /     \           `---' /  ;  |   :  | ; | '|   : '  '; |:   |  ;/|
*     '   :  ;  |  |   /' : /    /  |            /  ;  /   .   |  ' ' ' :'   ' ;.    ;|   :   .'
*     |   |  '  '  :  | | |.    ' / |           ;  /  /--, '   ;  \; /  ||   | | \   ||   |  |-,
*     '   :  |  |  |  ' | :'   ;   /|          /  /  / .`|  \   \  ',  / '   : |  ; .''   :  ;/|
*     ;   |.'   |  :  :_:,''   |  / |        ./__;       :   ;   :    /  |   | '`--'  |   |    \
*     '---'     |  | ,'    |   :    |        |   :     .'     \   \ .'   '   : |      |   :   .'
*               `--''       \   \  /         ;   |  .'         `---`     ;   |.'      |   | ,'
*                            `----'          `---'                       '---'        `----'
*                                                 Home of custom build re-usable components
*
"! Welcome to the ZONE documentation tool for re-usable components. Feel free to add your
"! own groups with classes, reports, function modules and tables directly into the source coding of
"! include ZONE_SCRIPT of this report.
"! <ul>
"! <li>ABAPdoc documentation on class/method/data definition and report headers is reported (html-style)</li>
"! <li>A group can have a description</li>
"! <li>Components can have:<ul>
"! <li>(a set of) #hashtag words </li>
"! <li>ABAPdoc style comments, embedded in the ZONE script </li>
"! <li>Reviews, where a user describes why something is good or not so good </li>
"! <li>Labeled links as URL for documentation references </li></ul></li>
"! <li>A component of type class can have a list of method names (to filter out methods that are not relevant to list)</li>
"! </ul>
REPORT zone.

DATA gv_okcode TYPE sy-ucomm.
DATA gt_documentheader TYPE STANDARD TABLE OF char255.
DATA: BEGIN OF gs_images,
        logo       TYPE c LENGTH 170,
        background TYPE c LENGTH 170,
      END OF gs_images.

CLASS lcl_event_receiver DEFINITION.
  PUBLIC SECTION.
    CLASS-METHODS handle_sapevent FOR EVENT sapevent OF cl_gui_html_viewer
      IMPORTING getdata query_table.
ENDCLASS.
CLASS lcl_document_groups DEFINITION DEFERRED.
CLASS lcl_component_documentor DEFINITION.

  PUBLIC SECTION.

    CONSTANTS: co_undetermined TYPE c LENGTH 20 VALUE '~???~',
               co_field_error  TYPE c LENGTH 25 VALUE  '<i>(no description)</i>'.
    TYPES: BEGIN OF gty_docline,
             linenr  TYPE i,
             content TYPE string,
           END OF gty_docline.
    TYPES: gty_doclines TYPE SORTED TABLE OF gty_docline WITH UNIQUE KEY linenr.
    TYPES: BEGIN OF gty_parameter,
             linenr     TYPE i,
             parameter  TYPE string,
             pardecltyp TYPE seopardecl, "0=importing, 1=exporting, 2= changing, 3= returning, 9=exception
             datatype   TYPE string,
             optional   TYPE boolean,
           END OF gty_parameter.
    TYPES: gty_parameters TYPE SORTED TABLE OF gty_parameter WITH UNIQUE KEY linenr.
    TYPES: BEGIN OF gty_class_details,
             author            TYPE vseoclass-author,
             createdon         TYPE vseoclass-createdon,
             changedby         TYPE vseoclass-changedby,
             changedon         TYPE vseoclass-changedon,
             superclass        TYPE seoclsname,
             interfaces        TYPE string,
             linecount         TYPE int4,
             methods           TYPE int4,
             redefinitions     TYPE int4,
             filter_on_methods TYPE boolean,
             message           TYPE string,
           END OF gty_class_details.
    TYPES: BEGIN OF gty_report_details,
             cnam      TYPE trdir-cnam,
             cdat      TYPE trdir-cdat,
             unam      TYPE trdir-unam,
             udat      TYPE trdir-udat,
             includes  TYPE SORTED TABLE OF char80 WITH UNIQUE KEY table_line,
             linecount TYPE sy-dbcnt,
           END OF gty_report_details.
    TYPES: BEGIN OF gty_function_details,
             author     TYPE tadir-author,
             created_on TYPE tadir-created_on,
             area       TYPE enlfdir-area,
             linecount  TYPE sy-dbcnt,
             hitcount   TYPE sy-dbcnt,
           END OF gty_function_details.
    TYPES: BEGIN OF gty_table_details,
             created_by  TYPE e070-as4user,
             created_on  TYPE e070-as4date,
             changed_by  TYPE dd02l-as4user,
             changed_on  TYPE dd02l-as4date,
             maintenance TYPE boolean,
             dd03l       TYPE SORTED TABLE OF dd03l WITH UNIQUE KEY position fieldname,
           END OF gty_table_details.
    TYPES: BEGIN OF gty_component,
             component_type  TYPE string,
             component_name  TYPE string,
             description     TYPE string,
             abapdoc         TYPE gty_doclines,
             attvalue        TYPE string,
             parameters      TYPE gty_parameters,
             read_only       TYPE boolean,
             method_hitcount TYPE sy-dbcnt,
             class           TYPE gty_class_details,
             report          TYPE gty_report_details,
             function        TYPE gty_function_details,
             table           TYPE gty_table_details,
             devclass        TYPE tadir-devclass,
             devclass_text   TYPE tdevct-ctext,
             redefinition    TYPE boolean,
           END OF gty_component.
    TYPES: BEGIN OF gty_user,
             user     TYPE sy-uname,
             fullname TYPE bapiaddr3-fullname,
           END OF gty_user.
    TYPES: BEGIN OF ty_devclass,
             devclass      TYPE tdevc-devclass,
             parentcl      TYPE tdevc-parentcl,
             ctext_E       TYPE tdevct-ctext,
             ctext_N       TYPE tdevct-ctext,
             relevant      TYPE boolean,
             objectcounter TYPE int2,
             tadircounter  TYPE int2,
           END OF ty_devclass.
    CLASS-DATA gt_devclass TYPE SORTED TABLE OF ty_devclass WITH UNIQUE KEY devclass
               WITH UNIQUE SORTED KEY via_parents COMPONENTS parentcl devclass.

    DATA gt_abap TYPE STANDARD TABLE OF string.
    DATA gt_components TYPE STANDARD TABLE OF gty_component.
    CLASS-DATA gt_users TYPE SORTED TABLE OF gty_user WITH UNIQUE KEY user.

    METHODS constructor IMPORTING iv_only_methods TYPE string  iv_type TYPE string iv_name TYPE string iv_abapdoc TYPE string.
    CLASS-METHODS get_zone_version RETURNING VALUE(rv_version_str) TYPE string.
    CLASS-METHODS get_username IMPORTING iv_user TYPE sy-uname RETURNING VALUE(rv_fullname) TYPE bapiaddr3-fullname.
    CLASS-METHODS get_sap_description
      IMPORTING fieldreference     TYPE any
                language           TYPE sy-langu DEFAULT sy-langu
      RETURNING VALUE(description) TYPE text80.
    CLASS-METHODS read_developmentclasses.

  PRIVATE SECTION.

    METHODS complex_definitions IMPORTING component_type TYPE string start_tabix TYPE sy-tabix.
    METHODS string_to_abapdoc IMPORTING iv_string TYPE string RETURNING VALUE(rt_abapdoc) TYPE gty_doclines.
    METHODS read_class IMPORTING iv_classname TYPE seoclsname iv_only_methods TYPE string iv_abapdoc TYPE string.
    METHODS read_report IMPORTING iv_report TYPE sy-repid iv_abapdoc TYPE string.
    METHODS read_table IMPORTING iv_table TYPE string iv_abapdoc TYPE string.
    METHODS read_function IMPORTING iv_function TYPE string iv_abapdoc TYPE string.

ENDCLASS.

CLASS lcl_document_groups DEFINITION.

  PUBLIC SECTION.
    TYPES: BEGIN OF gty_link,
             label TYPE string,
             link  TYPE string,
           END OF gty_link.
    TYPES: BEGIN OF gty_review,
             date     TYPE d,
             uname    TYPE sy-uname,
             username TYPE string,
             rating   TYPE n LENGTH 1, "0 to 5 stars
             summary  TYPE string,
             remarks  TYPE string,
           END OF gty_review.
    TYPES: BEGIN OF gty_playlistentry,
             object_type  TYPE string,
             object_name  TYPE string,
             tagwords     TYPE string,
             only_methods TYPE string, "Comma delimited list of method names that should be presented
             abapdoc      TYPE string,
             links        TYPE SORTED TABLE OF gty_link WITH UNIQUE KEY label link,
             reviews      TYPE SORTED TABLE OF gty_review WITH UNIQUE KEY date uname,
           END OF gty_playlistentry.
    TYPES gty_playlist TYPE STANDARD TABLE OF gty_playlistentry.
    TYPES: BEGIN OF gty_group_object,
             id          TYPE sy-tabix,
             object_type TYPE string,
             object_name TYPE string,
             components  TYPE REF TO lcl_component_documentor,
             links       TYPE SORTED TABLE OF gty_link WITH UNIQUE KEY label link,
             tagwords    TYPE string,
             reviews     TYPE SORTED TABLE OF gty_review WITH UNIQUE KEY date uname,
             created     TYPE d,
             changed     TYPE d,
           END OF gty_group_object.
    TYPES: BEGIN OF gty_group,
             description TYPE string,
             summary     TYPE string,
             objects     TYPE SORTED TABLE OF gty_group_object WITH UNIQUE KEY id,
             created     TYPE d,
             changed     TYPE d,
           END OF gty_group.
    TYPES: BEGIN OF gty_content,
             label     TYPE string,
             value     TYPE string,
             username  TYPE sy-uname,
             datevalue TYPE d,
           END OF gty_content.
    TYPES: gty_content_tt TYPE STANDARD TABLE OF gty_content.

    "SVG image repository
    DATA gt_svg_class TYPE STANDARD TABLE OF char255.
    DATA gt_svg_report TYPE STANDARD TABLE OF char255.
    DATA gt_svg_function TYPE STANDARD TABLE OF char255.
    DATA gt_svg_table TYPE STANDARD TABLE OF char255.
    DATA gv_svg_mini_icon TYPE char255.
    DATA gv_svg_mini_icon2 TYPE char255.
    DATA gt_svg_exporting TYPE STANDARD TABLE OF char255.
    DATA gt_svg_importing TYPE STANDARD TABLE OF char255.
    DATA gt_svg_changing TYPE STANDARD TABLE OF char255.
    DATA gt_svg_returning TYPE STANDARD TABLE OF char255.
    DATA gt_svg_parameter TYPE STANDARD TABLE OF char255.
    DATA gt_svg_selectoption TYPE STANDARD TABLE OF char255.
    DATA gt_svg_exception TYPE STANDARD TABLE OF char255.
    DATA gt_svg_screw TYPE STANDARD TABLE OF char255.
    DATA gt_svg_star_empty TYPE STANDARD TABLE OF char255.
    DATA gt_svg_star TYPE STANDARD TABLE OF char255.
    DATA gt_svg_lapse TYPE STANDARD TABLE OF char255.

    DATA go_html_control TYPE REF TO cl_gui_html_viewer.
    DATA go_container TYPE REF TO cl_gui_custom_container.
    DATA gt_myevents TYPE cntl_simple_events.
    DATA go_event_receiver TYPE REF TO lcl_event_receiver.
    DATA gt_html TYPE STANDARD TABLE OF char255.
    DATA gv_url TYPE c LENGTH 200.
    DATA: BEGIN OF gs_counters,
            groups       TYPE i,
            objects      TYPE i,
            classes      TYPE i,
            methods      TYPE i,
            classmethods TYPE i,
            tables       TYPE i,
            reports      TYPE i,
            functions    TYPE i,
          END OF gs_counters.

    CLASS-DATA gt_groups TYPE STANDARD TABLE OF gty_group.
    CLASS-DATA gv_id TYPE sy-tabix.
    CLASS-METHODS set_group IMPORTING iv_description TYPE string iv_summary TYPE string DEFAULT '' it_playlist TYPE gty_playlist.

    METHODS string_to_html IMPORTING iv_string TYPE string.
    METHODS set_html_style.
    METHODS set_svg_images.
    METHODS set_age_color IMPORTING iv_date TYPE d RETURNING VALUE(rv_color) TYPE char10.
    METHODS harvest_counters.
    METHODS harvest_developmentclasses.
    METHODS print_developmentclass IMPORTING iv_level    TYPE int2
                                             iv_devclass TYPE lcl_component_documentor=>ty_devclass.
    METHODS harvest_dates.
    METHODS set_abapdoc IMPORTING it_abapdoc TYPE lcl_component_documentor=>gty_doclines.
    METHODS set_group_header IMPORTING iv_groupnr TYPE sy-tabix is_group TYPE gty_group.
    CLASS-METHODS get_date_summary IMPORTING iv_date TYPE d RETURNING VALUE(rv_result) TYPE string.
    METHODS set_all_tagwords IMPORTING is_group TYPE gty_group.
    METHODS set_tagwords IMPORTING iv_tagwords TYPE string.
    METHODS set_parameter_svg IMPORTING iv_parameter_type TYPE any.
    METHODS set_links IMPORTING is_object TYPE gty_group_object.
    METHODS set_reviews IMPORTING is_object TYPE gty_group_object.
    METHODS set_object_header IMPORTING is_object TYPE gty_group_object.
    METHODS set_group_detail IMPORTING iv_created_by TYPE sy-uname iv_created_on TYPE sy-datum it_content TYPE gty_content_tt.
    METHODS filter_focus IMPORTING iv_devclass TYPE devclass.
    METHODS zone_reporter.

  PRIVATE SECTION.
    METHODS mini_dot_as_svg
      IMPORTING iv_object_type        TYPE string
                iv_medium             TYPE boolean DEFAULT abap_false
      RETURNING VALUE(rv_colored_dot) TYPE char255.

ENDCLASS.

CLASS lcl_event_receiver IMPLEMENTATION.
  METHOD handle_sapevent.
    DATA lv_devclass TYPE devclass.

    SPLIT getdata AT '=' INTO TABLE DATA(lt_tokens).
    lv_devclass = COND #( WHEN lines( lt_tokens ) = 2 THEN lt_tokens[ 2 ] ELSE '' ).
    "Execute a refresh
    SUBMIT zone WITH pa_devcl = lv_devclass.

  ENDMETHOD.
ENDCLASS.

CLASS lcl_component_documentor IMPLEMENTATION.

  METHOD constructor.

    CASE iv_type.
      WHEN 'CLASS'.
        read_class( iv_classname = |{ iv_name }| iv_only_methods = iv_only_methods iv_abapdoc = iv_abapdoc ).
      WHEN 'REPORT'.
        read_report( iv_report = |{ iv_name }| iv_abapdoc = iv_abapdoc ).
      WHEN 'TABLE'.
        read_table( iv_table = |{ iv_name }| iv_abapdoc = iv_abapdoc ).
      WHEN 'FUNCTION'.
        read_function( iv_function = |{ iv_name }| iv_abapdoc = iv_abapdoc ).
    ENDCASE.

  ENDMETHOD.

  METHOD complex_definitions.
    DATA lv_finish_tabix TYPE sy-tabix.
    DATA lt_cleanabap TYPE STANDARD TABLE OF string.
    DATA lv_cleanabapline TYPE string.
    DATA lv_structurevariabele TYPE string.
    DATA lt_abapdoc TYPE gty_doclines.
    DATA lv_component_type TYPE string.
    DATA lv_value TYPE string.
    FIELD-SYMBOLS <ls_component> TYPE gty_component.

    lv_component_type = to_upper( component_type ).
    REPLACE ':' IN lv_component_type WITH ''.
    "Focus on the coding between : and . - first find the . (dot)
    LOOP AT gt_abap FROM start_tabix INTO DATA(lv_abapline).
      DATA(lv_loop_tabix) = sy-tabix.
      SHIFT lv_abapline LEFT DELETING LEADING space.

      "Opening line: remove the component_type
      IF lv_loop_tabix = start_tabix.
        SHIFT lv_abapline LEFT BY strlen( component_type ) PLACES.
      ENDIF.
      CONDENSE lv_abapline.

      " ABAP doc comments
      IF strlen( lv_abapline ) > 3 AND lv_abapline(2) = '"!'.
        APPEND lv_abapline TO lt_cleanabap.
        CONTINUE.
      ENDIF.
      SPLIT lv_abapline AT '"' INTO lv_abapline DATA(lv_comments). "Strip comments
      lv_cleanabapline = |{ lv_cleanabapline } { lv_abapline }|.
      IF lv_cleanabapline CA '.,'.
        SHIFT lv_cleanabapline LEFT DELETING LEADING space.
        "Cut out the TYPE definition
        SPLIT lv_cleanabapline AT space INTO TABLE DATA(lt_tokens).
        IF lines( lt_tokens ) > 2.
          IF to_upper( lt_tokens[ 2 ] ) = 'TYPE'.
            "TYPE REF TO
            IF to_upper( lt_tokens[ 3 ] ) = 'REF'.
              DELETE lt_tokens FROM 2 TO 5.
            ELSE.
              DELETE lt_tokens FROM 2 TO 3.
            ENDIF.
          ELSEIF to_upper( lt_tokens[ 2 ] ) = 'FOR' OR to_upper( lt_tokens[ 2 ] ) = 'LIKE'.
            DELETE lt_tokens FROM 2 TO 3.
          ENDIF.
        ENDIF.
        CLEAR lv_cleanabapline.
        LOOP AT lt_tokens INTO DATA(lv_token).
          CONCATENATE lv_cleanabapline lv_token INTO lv_cleanabapline SEPARATED BY space.
        ENDLOOP.
        SHIFT lv_cleanabapline LEFT DELETING LEADING space.
        REPLACE ',' IN lv_cleanabapline  WITH ''.
        APPEND lv_cleanabapline TO lt_cleanabap.
        CLEAR lv_cleanabapline.

      ENDIF.

      IF lv_abapline CS '.'.
        lv_finish_tabix = sy-tabix.
        EXIT.
      ENDIF.
    ENDLOOP.

    LOOP AT lt_cleanabap INTO lv_cleanabapline.

      IF strlen( lv_cleanabapline ) > 2 AND lv_cleanabapline(2) = '"!'.
        INSERT VALUE gty_docline( linenr = lines( lt_abapdoc ) content = lv_cleanabapline+2 ) INTO TABLE lt_abapdoc.
        CONTINUE.
      ENDIF.
      SPLIT lv_cleanabapline AT space INTO TABLE lt_tokens.

      CASE lv_component_type.
        WHEN 'SELECT-OPTIONS' OR 'PARAMETERS'.

        WHEN OTHERS.
          IF to_upper( lt_tokens[ 1 ] ) = 'BEGIN'.
            lv_structurevariabele = |{ to_upper( lt_tokens[ 3 ] ) }|.
            APPEND VALUE gty_component(
              component_type = lv_component_type
              component_name = lv_structurevariabele ) TO gt_components ASSIGNING <ls_component>.
            APPEND LINES OF lt_abapdoc TO <ls_component>-abapdoc.
            CLEAR lt_abapdoc.
*            lv_structurevariabele = '&nbsp;&nbsp;&nbsp;&nbsp;'.
            CLEAR lv_structurevariabele.

            CONTINUE.
          ENDIF.
          IF to_upper( lt_tokens[ 1 ] ) = 'END'.
            CLEAR lv_structurevariabele.
            CONTINUE.
          ENDIF.
      ENDCASE.

      lv_value = COND #( WHEN ( lines( lt_tokens ) >= 3 ) AND ( to_upper( lt_tokens[ 2 ] ) = 'VALUE' ) THEN lt_tokens[ 3 ] ELSE '' ).
      APPEND VALUE gty_component(
        component_type = lv_component_type
        component_name = |{ lv_structurevariabele }{ to_upper( lt_tokens[ 1 ] ) }|
        attvalue =  lv_value ) TO gt_components ASSIGNING <ls_component>.
      APPEND LINES OF lt_abapdoc TO <ls_component>-abapdoc.
      CLEAR lt_abapdoc.
    ENDLOOP.

    IF lv_finish_tabix > 0. "Structure too complex if no end line available
      lv_finish_tabix = lv_finish_tabix + start_tabix.
      "Clean up the block of coding that was interpreted - to ensure the regular processing remains
      LOOP AT gt_abap FROM start_tabix TO lv_finish_tabix ASSIGNING FIELD-SYMBOL(<ls_abap>).
        CLEAR <ls_abap>.
      ENDLOOP.
    ENDIF.

  ENDMETHOD.

  METHOD string_to_abapdoc.
    DATA lt_string_components TYPE STANDARD TABLE OF swastrtab.

    CHECK strlen( iv_string ) > 0.
    CALL FUNCTION 'SWA_STRING_SPLIT'
      EXPORTING
        input_string         = iv_string
        max_component_length = 70
      TABLES
        string_components    = lt_string_components.
    LOOP AT lt_string_components INTO DATA(ls_string_component).
      APPEND VALUE #( linenr = lines( rt_abapdoc ) content = ls_string_component-str ) TO rt_abapdoc.
    ENDLOOP.

  ENDMETHOD.

  METHOD get_zone_version.

    SELECT SINGLE unam, udat FROM trdir INTO @DATA(ls_trdir) WHERE name = 'ZONE_SCRIPT'.
    IF ls_trdir-udat = sy-datum.
      rv_version_str =
        |Last <b>zone_script</b> update <b>today</b> by { get_username( ls_trdir-unam ) } ({ ls_trdir-unam })|.
    ELSE.
      rv_version_str =
        |Last <b>zone_script</b> update on { ls_trdir-udat DATE = USER } ({ lcl_document_groups=>get_date_summary( iv_date = ls_trdir-udat ) }) | &&
        | by { get_username( ls_trdir-unam ) } ({ ls_trdir-unam })|.
    ENDIF.
    rv_version_str = |<span class=clickable onclick=INPUT.devclass.value="";INPUT.submit();>{ rv_version_str } (<i>click to refresh</i>)</span>|.

  ENDMETHOD.

  METHOD get_username.

    DATA ls_address TYPE bapiaddr3.
    DATA lt_return TYPE STANDARD TABLE OF bapiret2.

    READ TABLE gt_users WITH KEY user = iv_user INTO DATA(ls_user).
    IF sy-subrc <> 0.
      CALL FUNCTION 'BAPI_USER_GET_DETAIL'
        EXPORTING
          username = iv_user
        IMPORTING
          address  = ls_address
        TABLES
          return   = lt_return.

      ls_user = VALUE #( user = iv_user fullname = ls_address-fullname ).
      INSERT ls_user INTO TABLE gt_users.
    ENDIF.

    rv_fullname = ls_user-fullname.

  ENDMETHOD.

  METHOD get_sap_description.
    DATA: lv_tabname     TYPE c LENGTH 20,
          lv_fieldname   TYPE c LENGTH 25,
          lv_description TYPE dd03t-ddtext,
          lv_rollname    TYPE dd03l-rollname.

* Fetch SAP description if possible:
    CLEAR lv_description.
    IF NOT fieldreference IS INITIAL.
      lv_description = co_undetermined.
      SPLIT fieldreference AT '-' INTO lv_tabname lv_fieldname.

      IF NOT lv_fieldname IS INITIAL.
        SELECT ddtext FROM dd03t INTO lv_description
          UP TO 1 ROWS
          WHERE tabname = lv_tabname AND
                fieldname = lv_fieldname AND
                as4local = 'A' AND
                ddlanguage = language.
        ENDSELECT.
        IF sy-subrc <> 0 OR lv_description IS INITIAL.
          SELECT rollname FROM dd03l INTO lv_rollname
            UP TO 1 ROWS
            WHERE tabname = lv_tabname AND
                  fieldname = lv_fieldname AND
                  as4local = 'A' AND as4vers = 0000.
          ENDSELECT.
          IF sy-subrc = 0.
            SELECT SINGLE scrtext_l FROM dd04t INTO @DATA(lv_scrtext_l)
              WHERE rollname = @lv_rollname AND
                    ddlanguage = @language AND
                    as4local = 'A' AND as4vers = 0000.
            IF sy-subrc = 0.
              lv_description = lv_scrtext_l.
            ELSE.
              lv_description = co_field_error.
            ENDIF.
          ENDIF.
        ENDIF.
      ELSE.
* Structure name ?
        SELECT ddtext FROM dd02t INTO lv_description
          UP TO 1 ROWS
          WHERE tabname = lv_tabname AND
                as4local = 'A' AND
                ddlanguage = language.
        ENDSELECT.
        IF sy-subrc = 0.
          CONCATENATE 'Structure' lv_description INTO lv_description SEPARATED BY space.
        ENDIF.
      ENDIF.
    ENDIF.

    description = lv_description.
    REPLACE ALL OCCURRENCES OF '"' IN description WITH '#'.
  ENDMETHOD.

  METHOD read_class.
    DATA lv_classname TYPE seoclskey.
    DATA lt_abapdoc TYPE gty_doclines.
    DATA lo_cls TYPE REF TO if_oo_class_incl_naming.
    DATA lv_moving_component_type TYPE string.
    DATA lt_only_methods TYPE SORTED TABLE OF string WITH UNIQUE KEY table_line.
    DATA lv_lines TYPE sy-index.
    DATA lv_helper TYPE c LENGTH 100.
    FIELD-SYMBOLS <ls_component> TYPE gty_component.

    IF NOT iv_abapdoc IS INITIAL.
      APPEND LINES OF string_to_abapdoc( iv_abapdoc ) TO lt_abapdoc.
    ENDIF.

    IF NOT iv_only_methods IS INITIAL.
      SPLIT to_upper( iv_only_methods ) AT ',' INTO TABLE DATA(lt_tokens).
      LOOP AT lt_tokens INTO DATA(lv_token).
        CONDENSE lv_token NO-GAPS.
        READ TABLE lt_only_methods WITH KEY table_line = lv_token TRANSPORTING NO FIELDS.
        IF sy-subrc <> 0.
          INSERT lv_token INTO TABLE lt_only_methods.
        ENDIF.
      ENDLOOP.
    ENDIF.
    "Class interrogation - is this a valid class ? Gather details:
    TRY.
        DATA(lo_oo_class) = cl_oo_class=>get_instance( clsname = iv_classname ).
        DATA(lo_oo_class2) = NEW cl_oo_class( clsname = iv_classname ).
        lv_classname = iv_classname.

* Source for this technique: report dsmy_class_output
        CALL METHOD cl_oo_include_naming=>get_instance_by_cifkey
          EXPORTING
            cifkey = lv_classname
          RECEIVING
            cifref = DATA(lo_cif)
          EXCEPTIONS
            OTHERS = 1.

        lo_cls ?= lo_cif.

        READ REPORT lo_cls->main_source INTO gt_abap.
        IF sy-subrc <> 0.
          DATA(lv_message) = 'Inaccurate line count - main source unavailable'.
        ENDIF.
        lv_lines = lines( gt_abap ).

        READ REPORT lo_cls->public_section INTO gt_abap.
        "Translate the public section of the class to a list of constants and methods
        LOOP AT gt_abap INTO DATA(lv_abapline).
          DATA(lv_loop_tabix) = sy-tabix.
          SHIFT lv_abapline LEFT DELETING LEADING space.
          DATA(lv_abaplineupper) = to_upper( lv_abapline ).
          SPLIT lv_abaplineupper AT '.' INTO lv_abaplineupper DATA(lv_dummy).
          SPLIT lv_abaplineupper AT space INTO TABLE DATA(lt_abapline_tokens).

          "Abap DOC comments are for a statement that follows the comments. To ensure comments
          "are not added to a statement by accident, some checks are applied:
          IF strlen( lv_abapline ) = 0.
            CLEAR lt_abapdoc.
          ELSEIF strlen( lv_abapline ) > 3 AND lv_abapline(2) <> '"!' AND NOT lv_dummy IS INITIAL.
            CLEAR lt_abapdoc.
          ENDIF.

          " ABAP doc comments
          IF strlen( lv_abapline ) > 3 AND lv_abapline(2) = '"!'.
            INSERT VALUE gty_docline( linenr = lines( lt_abapdoc ) content = lv_abapline+2 ) INTO TABLE lt_abapdoc.

          ELSEIF
            ( lines( lt_abapline_tokens ) >= 1 ) AND
            ( ( strlen( lv_abaplineupper ) >= 10 AND lv_abaplineupper(10) = 'CONSTANTS:' ) OR
              ( strlen( lv_abaplineupper ) >= 5 AND lv_abaplineupper(5) = 'DATA:' ) OR
              ( strlen( lv_abaplineupper ) >= 11 AND lv_abaplineupper(11) = 'CLASS-DATA:' ) ).

            "Constants and attribute definitions with : are catered for differently. Multiple coding lines are
            "interpreted and required information is extracted. The extractor can clear gt_abap lines
            complex_definitions( component_type = lt_abapline_tokens[ 1 ] start_tabix = lv_loop_tabix ).

            "Attribute definitions (DATA and CLASS-DATA)
          ELSEIF  ( lines( lt_abapline_tokens ) > 1 ) AND
            NOT lv_moving_component_type IS INITIAL.

            READ TABLE lo_oo_class->attributes INTO DATA(ls_attribute_details)
              WITH KEY clsname = lv_classname cmpname = lt_abapline_tokens[ 1 ].
            IF sy-subrc = 0.
              APPEND VALUE gty_component(
                component_type = lv_moving_component_type
                component_name = ls_attribute_details-cmpname
                attvalue = ls_attribute_details-attvalue
                read_only = ls_attribute_details-attrdonly ) TO gt_components ASSIGNING <ls_component>.
              APPEND LINES OF lt_abapdoc TO <ls_component>-abapdoc.
            ENDIF.
            CLEAR lt_abapdoc.

          ELSEIF
            ( lines( lt_abapline_tokens ) > 1 ) AND
            ( ( strlen( lv_abaplineupper ) > 9 AND lv_abaplineupper(9) = 'CONSTANTS' ) OR
              ( strlen( lv_abaplineupper ) > 4 AND lv_abaplineupper(4) = 'DATA' ) OR
              ( strlen( lv_abaplineupper ) > 10 AND lv_abaplineupper(10) = 'CLASS-DATA' ) ).

            READ TABLE lo_oo_class->attributes INTO ls_attribute_details
              WITH KEY clsname = lv_classname cmpname = lt_abapline_tokens[ 2 ].
            IF sy-subrc = 0.
              APPEND VALUE gty_component(
                component_type = lt_abapline_tokens[ 1 ]
                component_name = ls_attribute_details-cmpname
                attvalue = ls_attribute_details-attvalue
                read_only = ls_attribute_details-attrdonly ) TO gt_components ASSIGNING <ls_component>.
              APPEND LINES OF lt_abapdoc TO <ls_component>-abapdoc.
            ENDIF.
            CLEAR lt_abapdoc.

            "CLASS METHOD definition as well as METHOD definition
          ELSEIF
            ( strlen( lv_abaplineupper ) > 12 AND lv_abaplineupper(12) = 'CLASS-METHOD' ) OR
            ( strlen( lv_abaplineupper ) > 6 AND lv_abaplineupper(6) = 'METHOD' ).

            READ TABLE lo_oo_class->methods INTO DATA(ls_method_details)
              WITH KEY clsname = lv_classname cmpname = lt_abapline_tokens[ 2 ].
            IF sy-subrc = 0.
              IF lines( lt_only_methods ) > 0.
                READ TABLE lt_only_methods WITH KEY table_line = to_upper( lt_abapline_tokens[ 2 ] ) TRANSPORTING NO FIELDS.
                IF sy-subrc <> 0.
                  CLEAR lt_abapdoc.
                  CONTINUE.
                ENDIF.
              ENDIF.

              APPEND VALUE gty_component(
                component_type = lt_abapline_tokens[ 1 ]
                component_name = ls_method_details-cmpname ) TO gt_components ASSIGNING <ls_component>.
              APPEND LINES OF lt_abapdoc TO <ls_component>-abapdoc.
              "Determine method hitcount (number of times it is called)
              DATA(lv_reference) = |{ iv_classname }\\ME:{ <ls_component>-component_name }|.
              SELECT COUNT(*) FROM wbcrossgt INTO @<ls_component>-method_hitcount
                WHERE otype = 'ME' AND name = @lv_reference.
              "Add method parameters - in sequence of type
              DO 4 TIMES.
                LOOP AT lo_oo_class->method_parameters INTO DATA(ls_method_parameter_details)
                  WHERE clsname =  ls_method_details-clsname AND cmpname = ls_method_details-cmpname AND
                    pardecltyp = ( sy-index - 1 ).
                  INSERT VALUE gty_parameter(
                    linenr = lines( <ls_component>-parameters )
                    parameter = ls_method_parameter_details-sconame
                    pardecltyp = ls_method_parameter_details-pardecltyp
                    datatype = ls_method_parameter_details-type
                    optional = ls_method_parameter_details-paroptionl ) INTO TABLE <ls_component>-parameters.
                ENDLOOP.
              ENDDO.
              "Exceptions
              LOOP AT lo_oo_class->method_exceptions INTO DATA(ls_method_exception_details)
                WHERE clsname =  ls_method_details-clsname AND cmpname = ls_method_details-cmpname.
                INSERT VALUE gty_parameter(
                  linenr = lines( <ls_component>-parameters )
                  parameter = ls_method_exception_details-sconame
                  pardecltyp = 9 ) INTO TABLE <ls_component>-parameters.
              ENDLOOP.
            ELSE.
              "Method is a redefinition
              READ TABLE lo_oo_class2->redefinitions INTO DATA(ls_refefinition_details)
                WITH KEY clsname = lv_classname mtdname = lt_abapline_tokens[ 2 ].
              IF sy-subrc = 0.
                IF lines( lt_only_methods ) > 0.
                  READ TABLE lt_only_methods WITH KEY table_line = to_upper( lt_abapline_tokens[ 2 ] ) TRANSPORTING NO FIELDS.
                  IF sy-subrc <> 0.
                    CLEAR lt_abapdoc.
                    CONTINUE.
                  ENDIF.
                ENDIF.

                APPEND VALUE gty_component(
                  component_type = lt_abapline_tokens[ 1 ]
                  component_name = ls_refefinition_details-mtdname
                  parameters = value #( ( linenr = 1 parameter = '?' pardecltyp = '2' ) )
                  redefinition = abap_true
                ) TO gt_components ASSIGNING <ls_component>.
                APPEND LINES OF lt_abapdoc TO <ls_component>-abapdoc.
                "Determine method hitcount (number of times it is called)
                lv_reference = |{ iv_classname }\\ME:{ <ls_component>-component_name }|.
                SELECT COUNT(*) FROM wbcrossgt INTO @<ls_component>-method_hitcount
                  WHERE otype = 'ME' AND name = @lv_reference.

              ENDIF.
            ENDIF.
            CLEAR lt_abapdoc.


            "CLASS definition
          ELSEIF strlen( lv_abaplineupper ) > 5 AND lv_abaplineupper(5) = 'CLASS'.
            IF lt_abapline_tokens[ 1 ] = 'CLASS' AND lt_abapline_tokens[ 3 ] = 'DEFINITION'.
              DATA lv_clsname TYPE vseoclass-clsname.
              lv_clsname = lv_classname.

              APPEND VALUE gty_component(
                component_type = lt_abapline_tokens[ 1 ]
                component_name = lv_classname
                class-superclass = lo_oo_class2->superclass
                class-methods = lines( lo_oo_class->methods )
                class-redefinitions = lines( lo_oo_class2->redefinitions )
              ) TO gt_components ASSIGNING <ls_component>.

              LOOP AT lo_oo_class2->implementings INTO DATA(ls_implementing).
                IF <ls_component>-class-interfaces IS INITIAL.
                  <ls_component>-class-interfaces = ls_implementing-refclsname.
                ELSE.
                  <ls_component>-class-interfaces = |{ <ls_component>-class-interfaces }, { ls_implementing-refclsname }|.
                ENDIF.
              ENDLOOP.

              <ls_component>-class-filter_on_methods = COND #( WHEN iv_only_methods IS INITIAL THEN abap_false ELSE abap_true ).

              SELECT SINGLE descript, author, createdon, changedby, changedon
                FROM vseoclass
                INTO (  @<ls_component>-description,  @<ls_component>-class-author, @<ls_component>-class-createdon,
                  @<ls_component>-class-changedby, @<ls_component>-class-changedon )
                WHERE clsname = @lv_clsname.
              <ls_component>-class-linecount = lv_lines.
              <ls_component>-class-message = lv_message.

              "Some effort to find an accurate last changed date (and user) - based on STMS
              lv_helper = |{ lv_clsname }%|.
              SELECT h~as4date, h~as4user FROM e070 AS h
                 INNER JOIN e071 AS o ON o~trkorr = h~trkorr
                 UP TO 1 ROWS INTO @DATA(ls_stms)
                 WHERE ( o~obj_name = @lv_clsname AND o~object IN ( 'CLAS', 'CLSD', 'CPUB' ) ) OR
                       ( o~obj_name LIKE @lv_helper AND o~object IN ( 'METH' ) )
                       ORDER BY h~as4date DESCENDING, h~as4time DESCENDING.
              ENDSELECT.
              IF sy-subrc = 0.
                <ls_component>-class-changedby = ls_stms-as4user.
                <ls_component>-class-changedon = ls_stms-as4date.
              ENDIF.

              APPEND LINES OF lt_abapdoc TO <ls_component>-abapdoc.

              SELECT SINGLE devclass FROM tadir INTO @<ls_component>-devclass
                WHERE pgmid = 'R3TR' AND object = 'CLAS' AND  obj_name = @<ls_component>-component_name.
              IF sy-subrc = 0.
                SELECT SINGLE ctext FROM tdevct INTO @<ls_component>-devclass_text
                  WHERE devclass = @<ls_component>-devclass AND spras = @sy-langu.
                IF sy-subrc <> 0.
                  SELECT SINGLE ctext FROM tdevct INTO @<ls_component>-devclass_text
                    WHERE devclass = @<ls_component>-devclass AND spras <> @sy-langu.
                ENDIF.
              ENDIF.

            ENDIF.
            CLEAR lt_abapdoc.

          ENDIF.

        ENDLOOP.
      CATCH  cx_class_not_existent.
        "skipped: not a class
    ENDTRY.

  ENDMETHOD.

  METHOD read_report.
    DATA lt_abapdoc TYPE gty_doclines.
    DATA lt_includes TYPE STANDARD TABLE OF char80.
    DATA lv_REPORT_tagged TYPE boolean.
    DATA lt_abap TYPE STANDARD TABLE OF string.
    DATA lt_RSEL_INFO TYPE STANDARD TABLE OF rsel_info.
    FIELD-SYMBOLS <ls_component> TYPE gty_component.

    IF NOT iv_abapdoc IS INITIAL.
      APPEND LINES OF string_to_abapdoc( iv_abapdoc ) TO lt_abapdoc.
    ENDIF.

    READ REPORT iv_report INTO gt_abap.

    "The report logic is interpreted for it's ABAPdoc comments
    LOOP AT gt_abap INTO DATA(lv_abapline).
      DATA(lv_loop_tabix) = sy-tabix.
      SHIFT lv_abapline LEFT DELETING LEADING space.
      DATA(lv_abaplineupper) = to_upper( lv_abapline ).
      SPLIT lv_abaplineupper AT '.' INTO lv_abaplineupper DATA(lv_dummy).
      SPLIT lv_abaplineupper AT space INTO TABLE DATA(lt_abapline_tokens).
      DELETE lt_abapline_tokens WHERE table_line = ''.

      " ABAP doc comments
      IF strlen( lv_abaplineupper ) > 3 AND lv_abaplineupper(2) = '"!'.
        INSERT VALUE gty_docline( linenr = lines( lt_abapdoc ) content = lv_abapline+3 ) INTO TABLE lt_abapdoc.

        " Report definitie
      ELSEIF ( strlen( lv_abaplineupper ) > 6 AND lv_abaplineupper(6) = 'REPORT' ) AND lv_REPORT_tagged = abap_false.
        lv_REPORT_tagged  = abap_true.
        APPEND VALUE gty_component(
          component_type = lt_abapline_tokens[ 1 ]
          component_name = lt_abapline_tokens[ 2 ]
          report-linecount = lines( gt_abap ) ) TO gt_components ASSIGNING <ls_component>.

        SELECT SINGLE cnam, cdat, unam, udat FROM trdir INTO
          (@<ls_component>-report-cnam, @<ls_component>-report-cdat,
           @<ls_component>-report-unam, @<ls_component>-report-udat)
          WHERE name = @<ls_component>-component_name.
        SELECT SINGLE text FROM trdirt INTO @<ls_component>-description
          WHERE name = @<ls_component>-component_name AND sprsl = @sy-langu.
        IF sy-subrc <> 0.
          SELECT text FROM trdirt INTO @<ls_component>-description
            WHERE name = @<ls_component>-component_name.
          ENDSELECT.
        ENDIF.

        SELECT SINGLE devclass FROM tadir INTO @<ls_component>-devclass
          WHERE pgmid = 'R3TR' AND object = 'PROG' AND  obj_name = @<ls_component>-component_name.
        IF sy-subrc = 0.
          SELECT SINGLE ctext FROM tdevct INTO @<ls_component>-devclass_text
            WHERE devclass = @<ls_component>-devclass AND spras = @sy-langu.
          IF sy-subrc <> 0.
            SELECT SINGLE ctext FROM tdevct INTO @<ls_component>-devclass_text
              WHERE devclass = @<ls_component>-devclass AND spras <> @sy-langu.
          ENDIF.
        ENDIF.

        CALL FUNCTION 'GET_INCLUDETAB'
          EXPORTING
            progname = <ls_component>-component_name
          TABLES
            incltab  = lt_includes.

        "Update the program line counter with include lines
        LOOP AT lt_includes INTO DATA(lv_include).
          READ REPORT lv_include INTO lt_abap.
          <ls_component>-report-linecount = <ls_component>-report-linecount + lines( lt_abap ).
        ENDLOOP.
        INSERT LINES OF lt_includes INTO TABLE <ls_component>-report-includes.

        CALL FUNCTION 'RS_SELECTIONS_DESCRIPTION_RFC'
          EXPORTING
            report         = iv_report
            default_values = ' '
          TABLES
            field_info     = lt_RSEL_INFO
          EXCEPTIONS
            OTHERS         = 0.

        LOOP AT lt_RSEL_INFO INTO DATA(ls_RSEL_INFO).
          APPEND VALUE gty_parameter(
            linenr = lines( <ls_component>-parameters )
            pardecltyp = COND #( WHEN ls_RSEL_INFO-kind = 'P' THEN '6' ELSE '7' )
            parameter = ls_RSEL_INFO-name ) TO <ls_component>-parameters.
        ENDLOOP.

        APPEND LINES OF lt_abapdoc TO <ls_component>-abapdoc.
        CLEAR lt_abapdoc.

      ENDIF.

    ENDLOOP.

  ENDMETHOD.

  METHOD read_table.
    DATA lt_abapdoc TYPE gty_doclines.

    IF NOT iv_abapdoc IS INITIAL.
      APPEND LINES OF string_to_abapdoc( iv_abapdoc ) TO lt_abapdoc.
    ENDIF.

    SELECT SINGLE ddtext FROM dd02t INTO @DATA(ls_description)
      WHERE tabname = @iv_table.

    CHECK sy-subrc = 0.
    APPEND VALUE gty_component(
      component_type = 'TABLE'
      description = ls_description
      component_name = |{ iv_table }| ) TO gt_components ASSIGNING FIELD-SYMBOL(<ls_component>).

    SELECT SINGLE as4user, as4date, mainflag FROM dd02l INTO @DATA(ls_dd02l)
      WHERE tabname = @iv_table AND
            as4local = 'A' AND
            as4vers = 0000.
    IF sy-subrc = 0.
      <ls_component>-table-changed_on = ls_dd02l-as4date.
      <ls_component>-table-changed_by = ls_dd02l-as4user.
      <ls_component>-table-maintenance = ls_dd02l-mainflag.
    ENDIF.

    SELECT SINGLE devclass FROM tadir INTO @<ls_component>-devclass
      WHERE pgmid = 'R3TR' AND object = 'TABL' AND  obj_name = @<ls_component>-component_name.
    IF sy-subrc = 0.
      SELECT SINGLE ctext FROM tdevct INTO @<ls_component>-devclass_text
        WHERE devclass = @<ls_component>-devclass AND spras = @sy-langu.
      IF sy-subrc <> 0.
        SELECT SINGLE ctext FROM tdevct INTO @<ls_component>-devclass_text
          WHERE devclass = @<ls_component>-devclass AND spras <> @sy-langu.
      ENDIF.

      SELECT e070~as4user, e070~as4date FROM e071
        INNER JOIN e070 ON e070~trkorr = e071~trkorr
        WHERE e071~pgmid = 'R3TR' AND
              e071~object = 'TABL' AND
              e071~obj_name = @<ls_component>-component_name
              ORDER BY e071~trkorr
              INTO @DATA(ls_e070) .
        "Fetch the creation date from transports
        <ls_component>-table-created_on = ls_e070-as4date.
        <ls_component>-table-created_by = ls_e070-as4user.
        EXIT.
      ENDSELECT.
    ENDIF.

    SELECT * FROM dd03l INTO TABLE @<ls_component>-table-dd03l
       WHERE tabname = @iv_table AND as4local = 'A' AND as4vers = 0000.
    <ls_component>-abapdoc = lt_abapdoc.

  ENDMETHOD.

  METHOD read_function.
    DATA lt_abapdoc TYPE gty_doclines.
    DATA lt_abap TYPE STANDARD TABLE OF string.
    DATA lv_include TYPE char40.

    IF NOT iv_abapdoc IS INITIAL.
      APPEND LINES OF string_to_abapdoc( iv_abapdoc ) TO lt_abapdoc.
    ENDIF.

    SELECT SINGLE enlfdir~area, tadir~author, tadir~devclass, tadir~created_on, tfdir~pname, tfdir~include FROM enlfdir
      INNER JOIN tadir ON tadir~obj_name = enlfdir~area AND tadir~pgmid = 'R3TR' AND tadir~object = 'FUGR'
      INNER JOIN tfdir ON tfdir~funcname = enlfdir~funcname
      INTO @DATA(ls_function_data)
      WHERE enlfdir~funcname = @iv_function.
*
    APPEND VALUE gty_component(
      component_type = 'FUNCTION'
      component_name = |{ iv_function }|
      devclass = ls_function_data-devclass
      function-author = ls_function_data-author
      function-created_on = ls_function_data-created_on
      function-area = ls_function_data-area
      ) TO gt_components ASSIGNING FIELD-SYMBOL(<ls_component>).

    SELECT stext FROM tftit INTO @<ls_component>-description
      WHERE funcname = @iv_function.
      EXIT.
    ENDSELECT.
    "Hitcounter
    SELECT COUNT(*) INTO @<ls_component>-function-hitcount
      FROM cross WHERE type = 'F' AND name = @iv_function.

    SELECT SINGLE ctext FROM tdevct INTO @<ls_component>-devclass_text
      WHERE devclass = @<ls_component>-devclass AND spras = @sy-langu.
    IF sy-subrc <> 0.
      SELECT SINGLE ctext FROM tdevct INTO @<ls_component>-devclass_text
        WHERE devclass = @<ls_component>-devclass AND spras <> @sy-langu.
    ENDIF.

    lv_include = |{ ls_function_data-pname+3 }U{ ls_function_data-include }|.
    READ REPORT lv_include INTO lt_abap.
    <ls_component>-function-linecount = lines( lt_abap ).
    <ls_component>-abapdoc = lt_abapdoc.

    SELECT parameter, paramtype  FROM fupararef INTO TABLE @DATA(lt_FUPARAREF)
      WHERE funcname = @iv_function AND r3state = 'A'.
    "Importing
    LOOP AT lt_FUPARAREF INTO DATA(ls_FUPARAREF) WHERE paramtype = 'I'.
      INSERT VALUE gty_parameter(
        linenr = lines( <ls_component>-parameters ) pardecltyp = '0'
        parameter = ls_FUPARAREF-parameter ) INTO TABLE <ls_component>-parameters.
    ENDLOOP.
    "Changing
    LOOP AT lt_FUPARAREF INTO ls_FUPARAREF WHERE paramtype = 'C'.
      INSERT VALUE gty_parameter(
        linenr = lines( <ls_component>-parameters ) pardecltyp = '2'
        parameter = ls_FUPARAREF-parameter ) INTO TABLE <ls_component>-parameters.
    ENDLOOP.
    "Exporting
    LOOP AT lt_FUPARAREF INTO ls_FUPARAREF WHERE paramtype = 'E'.
      INSERT VALUE gty_parameter(
        linenr = lines( <ls_component>-parameters ) pardecltyp = '1'
        parameter = ls_FUPARAREF-parameter ) INTO TABLE <ls_component>-parameters.
    ENDLOOP.
    "Tables
    LOOP AT lt_FUPARAREF INTO ls_FUPARAREF WHERE paramtype = 'T'.
      INSERT VALUE gty_parameter(
        linenr = lines( <ls_component>-parameters ) pardecltyp = '2'
        parameter = ls_FUPARAREF-parameter ) INTO TABLE <ls_component>-parameters.
    ENDLOOP.
    "Exceptions
    LOOP AT lt_FUPARAREF INTO ls_FUPARAREF WHERE paramtype = 'X'.
      INSERT VALUE gty_parameter(
        linenr = lines( <ls_component>-parameters ) pardecltyp = '9'
        parameter = ls_FUPARAREF-parameter ) INTO TABLE <ls_component>-parameters.
    ENDLOOP.

  ENDMETHOD.

  METHOD read_developmentclasses.

    DATA lr_devclass TYPE RANGE OF tdevc-devclass.
    DATA lr_objectnames type range of tadir-obj_name.

    lr_devclass = VALUE #( ( sign = 'I' option = 'CP' low = '$*' ) ( sign = 'I' option = 'CP' low = 'Z*' ) ( sign = 'I' option = 'CP' low = 'Y*' ) ).
    SELECT tdevc~devclass, tdevc~parentcl, tdevct_E~ctext, tdevct_N~ctext
      FROM tdevc
      LEFT OUTER JOIN tdevct AS tdevct_E
        ON tdevc~devclass = tdevct_E~devclass AND tdevct_E~spras = 'E'
      LEFT OUTER JOIN tdevct AS tdevct_N
        ON tdevc~devclass = tdevct_N~devclass AND tdevct_N~spras = 'N'
      INTO TABLE @gt_devclass
      WHERE tdevc~devclass IN @lr_devclass.

     lr_objectnames = VALUE #( ( sign = 'I' option = 'CP' low = 'Y*' ) ( sign = 'I' option = 'CP' low = 'Z*' ) ).
     select distinct devclass, count( * ) as counter from tadir
       into table @data(lt_tadircounts)
       WHERE obj_name in @lr_objectnames and
         devclass IN @lr_devclass
       group by devclass.

     loop at gt_devclass assigning field-symbol(<ls_devclass>).
       read table lt_tadircounts with key devclass = <ls_devclass>-devclass into data(ls_tadircount).
       if sy-subrc = 0.
         <ls_devclass>-tadircounter = ls_tadircount-counter.
       endif.
     endloop.

  ENDMETHOD.

ENDCLASS.

CLASS lcl_document_groups IMPLEMENTATION.

  METHOD set_group.
    DATA lv_space_counter TYPE n LENGTH 3.
    FIELD-SYMBOLS <ls_group> TYPE gty_group.
    FIELD-SYMBOLS <ls_object> TYPE gty_group_object.

    INSERT VALUE gty_group(  ) INTO TABLE gt_groups ASSIGNING <ls_group>.

    <ls_group>-description = iv_description.
    <ls_group>-summary = iv_summary.
    LOOP AT it_playlist INTO DATA(ls_playlist).
      IF ls_playlist-object_type = 'SPACE'.
        lv_space_counter = lv_space_counter + 1.
        ls_playlist-object_name = lv_space_counter.
      ENDIF.
      READ TABLE <ls_group>-objects WITH KEY
        object_type = ls_playlist-object_type
        object_name = ls_playlist-object_name ASSIGNING <ls_object>.
      IF sy-subrc <> 0.
        INSERT VALUE gty_group_object(
          id = lines( <ls_group>-objects )
          object_type =  ls_playlist-object_type
          object_name =  ls_playlist-object_name
          links = ls_playlist-links
          tagwords = ls_playlist-tagwords
          reviews = ls_playlist-reviews )
          INTO TABLE <ls_group>-objects ASSIGNING  <ls_object>.
      ENDIF.
      <ls_object>-components = NEW lcl_component_documentor(
        iv_only_methods = ls_playlist-only_methods
        iv_abapdoc = ls_playlist-abapdoc
        iv_name =  ls_playlist-object_name
        iv_type =  ls_playlist-object_type ).
    ENDLOOP.
  ENDMETHOD.

  METHOD string_to_html.
    DATA lt_string_components TYPE STANDARD TABLE OF swastrtab.

    CHECK strlen( iv_string ) > 0.
    CALL FUNCTION 'SWA_STRING_SPLIT'
      EXPORTING
        input_string         = iv_string
        max_component_length = 70
      TABLES
        string_components    = lt_string_components.
    LOOP AT lt_string_components INTO DATA(ls_string_component).
      APPEND ls_string_component-str TO gt_html.
    ENDLOOP.

  ENDMETHOD.

  METHOD set_html_style.
    gt_html = VALUE #(
  ( '<!DOCTYPE html><html><head><title>The Zone - inspiration for developers</title>')
  ( '<style>')
  ( 'body { font-family:arial;margin-left:20px;max-width:1200px; ')
  ( | background: no-repeat center center fixed;| )
  ( | background-size: cover;| )
  ( | background-image: { COND #( WHEN gs_images-background <> '' THEN | url({ gs_images-background });| ELSE |linear-gradient(to right,white,white,white,gray);| ) }| )
  ( 'div.object { background-image: linear-gradient(to top,lightgray,transparent,transparent,transparent,transparent);}')
  ( '.mainLabel { writing-mode:vertical-rl;text-orientation:mixed;border-radius:6px 0px 0px 0px;border:1px solid black; ')
  ( '  letter-spacing: 2px;background-color:green;color:white;font-size:small;font-weight:400;padding:5px; }' )
  ( '.parameterLabel { writing-mode:vertical-rl;text-orientation:mixed;border-radius:6px 0px 0px 0px;border:1px solid black; ')
  ( '  background-color:gray;color:white;font-size:small;font-weight:400;padding:5px; }' )
  ( '.parameterListing { vertical-align:middle;width:190px;max-width:190px;overflow: hidden; white-space: nowrap; } ')
  ( 'td.leftPanel {width:650px;max-width:650px;} ' )
  ( 'td.componentTitle {font-size:large;font-weight:700;width:600px;height:30px;}' )
  ( '.large {font-size:large;} ' )
  ( 'section { margin-left:90px;margin-right:120px;}' )
  ( 'table.countsummary { width:100%;background-color:lightgray; }' )
  ( 'table.countsummary tr td { color:darkblue;font-size:14pt;vertical-align:middle;opacity:0.5; }' )
  ( 'table.countsummary tr td i { font-size:11pt; }' )
  ( 'img { width:80%;border: 0.5px solid black;box-shadow: 5px 10px 8px 0px #888888; } ' )
  ( 'div.comments { color:darkblue; } ' )
  ( 'span.comments { color:darkblue; } ' )
  ( 'span.readonly { font-weight:700;font-size:small;margin-left:15px; } ' )
  ( 'span.hitcount { color:gray;font-size:small; } ' )
  ( 'span.version { font-size:11pt;border:1px solid black;border-radius:6px;padding:5px;color:white;background-color:gray;padding-left:20px;padding-right:20px; } ' )
  ( 'h1 { border-bottom:2px solid gray;margin-block-end:2px;font-size:18pt; }')
  ( 'h2 { font-size: 15pt;border-bottom:1px solid gray;width:560px;font-size:large; }')
  ( 'td {vertical-align:top;}' )
  ( 'td.leadColumn { width:50px;border-right:2px solid lightgray; }' )
  ( 'td.fieldlabel {width:100px;text-align:right;color:gray;font-size:9pt;}' )
  ( 'td.reviews {font-size:11pt;font-weight:500;text-decoration:underline;}' )
  ( 'td.r {text-align:right;background-color:#edf0f7;}' )
  ( 'p {margin-left:10px;margin-top: 2px;margin-bottom: 2px;}' )
  ( 'table.techDetail { margin-left:90px;width:600px;background-color:gray;color:white;font-size:10pt;padding:3px;border: 3px solid black;border-radius:4px;box-shadow: 6px 4px 6px 0px rgba(0,0,0,0.6);}' )
  ( 'table.techDetail tr td.label { color:lightgray;text-align:right; }' )
  ( 'table.bordered { margin-left:90px; width:80%; }' )
  ( 'table.bordered tr.header td { border:1px solid black;background:gray;color:white; }' )
  ( 'table.bordered tr td { border-bottom:0.5px solid lightgray; }' )
  ( '.clickable {cursor:pointer;}' )
  ( '.clickable:hover {background-color:darkblue;color:white; }' )
  ( '</style>')
  ( '</head><body>' ) ).

  ENDMETHOD.

  METHOD set_svg_images.
    gt_svg_class = VALUE #(
   ( '<svg height="65" width="150" xmlns="http://www.w3.org/2000/svg"> ' )
   ( '  <circle r="30" cx="33" cy="33" fill="blue" stroke="black" stroke-width="0.5" /> ' )
   ( '  <text x="10" y="48" fill="white" font-weight=800 stroke="black" font-size="38">Class</text></svg> ' ) ).

    gt_svg_report = VALUE #(
   ( '<svg height="65" width="150" xmlns="http://www.w3.org/2000/svg"> ' )
   ( '  <circle r="30" cx="33" cy="33" fill="purple" stroke="black" stroke-width="0.5" /> ' )
   ( '  <text x="10" y="48" fill="white" font-weight=800 stroke="black" font-size="38">Report</text></svg> ' ) ).

    gt_svg_function = VALUE #(
   ( '<svg height="65" width="150" xmlns="http://www.w3.org/2000/svg"> ' )
   ( '  <circle r="30" cx="33" cy="33" fill="red" stroke="black" stroke-width="0.5" /> ' )
   ( '  <text x="10" y="48" fill="white" font-weight=800 stroke="black" font-size="28">Function</text></svg> ' ) ).

    gt_svg_table = VALUE #(
   ( '<svg height="65" width="150" xmlns="http://www.w3.org/2000/svg"> ' )
   ( '  <circle r="30" cx="33" cy="33" fill="orange" stroke="black" stroke-width="0.5" /> ' )
   ( '  <text x="10" y="48" fill="white" font-weight=800 stroke="black" font-size="38">Table</text></svg> ' ) ).

    gv_svg_mini_icon =
     '<svg height="21" width="22" xmlns="http://www.w3.org/2000/svg"><circle r="9" cx="10" cy="10" fill="BLACK" stroke="black" stroke-width="0.5" />' &&
     '<text x="3" y="15" fill="white" font-size="12">TEXT</text></svg> '.
    gv_svg_mini_icon2 =
     '<svg height="25" width="26" xmlns="http://www.w3.org/2000/svg"><circle r="11" cx="12" cy="12" fill="BLACK" stroke="black" stroke-width="0.5" />' &&
     '<text x="3" y="18" fill="white" font-size="14">TEXT</text></svg> '.

* https://www.svgrepo.com/collection/solar-line-duotone-icons/19
    gt_svg_exporting = VALUE #(
    ( '<div title="Exporting"><svg width="25px" height="25px" viewBox="0 0 24 24" fill="#33CC77" xmlns="http://www.w3.org/2000/svg">' )
    ( '<circle opacity="0.5" cx="12" cy="12" r="10" stroke="#1C274C" stroke-width="1.5"/>' )
    ( '<path d="M8 12C12.6863 12 11.3137 12 16 12M16 12L13 9M16 12L13 15" stroke="#1C274C" stroke-width="1.5" stroke-linecap="round" stroke-linejoin="round"/></svg></div>' ) ).
    gt_svg_importing = VALUE #(
    ( '<div title="Importing"><svg width="25px" height="25px" viewBox="0 0 24 24" fill="#5599EE" xmlns="http://www.w3.org/2000/svg">' )
    ( '<circle opacity="0.5" cx="12" cy="12" r="10" stroke="#1C274C" stroke-width="1.5"/>' )
    ( '<path d="M16 12H8M8 12L11 9M8 12L11 15" stroke="#1C274C" stroke-width="1.5" stroke-linecap="round" stroke-linejoin="round"/></svg></div>' ) ).
    gt_svg_changing = VALUE #(
    ( '<div title="Changing"><svg width="25px" height="25px" viewBox="0 0 24 24" fill="#33CC77" xmlns="http://www.w3.org/2000/svg">' )
    ( '<circle opacity="0.5" cx="12" cy="12" r="10" stroke="#1C274C" stroke-width="1.5"/>' )
    ( '<path d="M16 9.5L8 9.5M8 9.5L10.75 7M8 9.5L10.75 12" stroke="#1C274C" stroke-width="1.5" stroke-linecap="round" stroke-linejoin="round"/>' )
    ( '<path d="M8 14.5L16 14.5M16 14.5L13.25 12M16 14.5L13.25 17" stroke="#1C274C" stroke-width="1.5" stroke-linecap="round" stroke-linejoin="round"/></svg></div>' ) ).
    gt_svg_returning = VALUE #(
    ( '<div title="Returning"><svg width="25px" height="25px" viewBox="0 0 24 24" fill="#5599EE" xmlns="http://www.w3.org/2000/svg">' )
    ( '<circle opacity="0.5" cx="12" cy="12" r="10" stroke="#1C274C" stroke-width="1.5"/>' )
    ( '<path d="M15.5 9L12.5 12L15.5 15" stroke="#1C274C" stroke-width="1.5" stroke-linecap="round" stroke-linejoin="round"/>' )
    ( '<path d="M11.5 9L8.5 12L11.5 15" stroke="#1C274C" stroke-width="1.5" stroke-linecap="round" stroke-linejoin="round"/></svg></div>' ) ).
    gt_svg_parameter = VALUE #(
    ( '<div title="Parameter"><svg width="25px" height="25px" viewBox="0 0 24 24" fill="#33CC77" xmlns="http://www.w3.org/2000/svg">' )
    ( '<circle opacity="0.5" cx="12" cy="12" r="10" stroke="#1C274C" stroke-width="1.5"/>' )
    ( '<path d="M10.5 9L13.5 12L10.5 15" stroke="#1C274C" stroke-width="1.5" stroke-linecap="round" stroke-linejoin="round"/></svg></div>' ) ).
    gt_svg_selectoption = VALUE #(
    ( '<div title="Select-options"><svg width="25px" height="25px" viewBox="0 0 24 24" fill="#33CC77" xmlns="http://www.w3.org/2000/svg">' )
    ( '<circle opacity="0.5" cx="12" cy="12" r="10" stroke="#1C274C" stroke-width="1.5"/>' )
    ( '<path d="M8.5 9L11.5 12L8.5 15" stroke="#1C274C" stroke-width="1.5" stroke-linecap="round" stroke-linejoin="round"/>' )
    ( '<path d="M12.5 9L15.5 12L12.5 15" stroke="#1C274C" stroke-width="1.5" stroke-linecap="round" stroke-linejoin="round"/></svg></div>' ) ).
    gt_svg_exception = VALUE #(
    ( '<div title="Exception"><svg width="25px" height="25px" viewBox="0 0 24 24" fill="#ffd500" xmlns="http://www.w3.org/2000/svg">' )
    ( '<circle opacity="0.5" cx="12" cy="12" r="10" stroke="#1c274c" stroke-width="1.5"/>' )
    ( '<path d="M9 17C9.85038 16.3697 10.8846 16 12 16C13.1154 16 14.1496 16.3697 15 17" stroke="#1c274c" stroke-width="1.5" stroke-linecap="round"/>' )
    ( '<ellipse cx="15" cy="10.5" rx="1" ry="1.5" fill="#1c274c"/>' )
    ( '<ellipse cx="9" cy="10.5" rx="1" ry="1.5" fill="#1c274c"/></svg></div>' ) ).

    gt_svg_screw = VALUE #(
    ( '<svg height="25px" width="25px" version="1.1" id="Capa_1" xmlns="http://www.w3.org/2000/svg" xmlns:xlink="http://www.w3.org/1999/xlink" viewBox="0 0 155.695 155.695" xml:space="preserve">' )
    ( '<g><path style="fill:#1D1D1B;" d="M107.398,8.443c-0.813-2.032-2.474-3.608-4.546-4.313C94.803,1.39,86.41,0,77.906,0 C48.793,0,22.338,16.017,8.864,41.801C0.207,58.369-2.201,77.502,2.082,95.675c4.239,17.982,14.725,33.891,29.526,44.794' )
    ( '  c1.301,0.959,2.862,1.462,4.448,1.462c0.563,0,1.13-0.063,1.689-0.192c2.133-0.493,3.944-1.894,4.958-3.834l64.378-123.201 C108.096,12.763,108.211,10.477,107.398,8.443z M33.761,122.63C14.491,103.592,9.323,73.313,22.159,48.748' )
    ( '  C33.036,27.932,54.398,15,77.906,15c3.885,0,7.742,0.359,11.536,1.073L33.761,122.63z"/>' )
    ( '<path style="fill:#1D1D1B;" d="M153.613,60.021c-4.239-17.982-14.725-33.892-29.527-44.795c-1.763-1.3-4.005-1.762-6.138-1.27 c-2.133,0.493-3.944,1.894-4.958,3.834L48.613,140.992c-1.014,1.94-1.129,4.227-0.316,6.26c0.813,' )
    ( '  2.032,2.474,3.608,4.546,4.313 c8.047,2.74,16.44,4.129,24.945,4.13c0.003,0,0.003,0,0.006,0c29.108,0,55.563-16.018,69.036-41.801 C155.488,97.327,157.897,78.193,153.613,60.021z M133.536,106.947c-10.878,20.817-32.236,33.749-55.742,33.748' )
    ( '  c-0.001,0-0.004,0-0.005,0c-3.886,0-7.743-0.36-11.536-1.073l55.68-106.557C141.204,52.104,146.372,82.383,133.536,106.947z"/></g></svg>' ) ).

    gt_svg_star = VALUE #(
    ( '<svg width="24px" height="24px" viewBox="0 0 24 24" fill="yellow" xmlns="http://www.w3.org/2000/svg"> ' )
    ( '<path d="M9.15316 5.40838C10.4198 3.13613 11.0531 2 12 2C12.9469 2 13.5802 3.13612 14.8468 5.40837L15.1745 5.99623C15.5345 6.64193 15.7144 6.96479 15.9951 7.17781C16.2757 7.39083 16.6251 7.4699 17.3241 ' )
    ( '7.62805L17.9605 7.77203C20.4201 8.32856 21.65 8.60682 21.9426 9.54773C22.2352 10.4886 21.3968 11.4691 19.7199 13.4299L19.2861 13.9372C18.8096 14.4944 18.5713 14.773 18.4641 15.1177C18.357 15.4624 18.393 ' )
    ( '15.8341 18.465 16.5776L18.5306 17.2544C18.7841 19.8706 18.9109 21.1787 18.1449 21.7602C17.3788 22.3417 16.2273 21.8115 13.9243 20.7512L13.3285 20.4768C12.6741 20.1755 12.3469 20.0248 12 20.0248C11.6531 ' )
    ( '20.0248 11.3259 20.1755 10.6715 20.4768L10.0757 20.7512C7.77268 21.8115 6.62118 22.3417 5.85515 21.7602C5.08912 21.1787 5.21588 19.8706 5.4694 17.2544L5.53498 16.5776C5.60703 15.8341 5.64305 15.4624 ' )
    ( '5.53586 15.1177C5.42868 14.773 5.19043 14.4944 4.71392 13.9372L4.2801 13.4299C2.60325 11.4691 1.76482 10.4886 2.05742 9.54773C2.35002 8.60682 3.57986 8.32856 6.03954 7.77203L6.67589 7.62805C7.37485 ' )
    ( '7.4699 7.72433 7.39083 8.00494 7.17781C8.28555 6.96479 8.46553 6.64194 8.82547 5.99623L9.15316 5.40838Z" stroke="#1C274C" stroke-width="1.5"/></svg> ' ) ).
    gt_svg_star_empty = VALUE #(
    ( '<svg width="24px" height="24px" viewBox="0 0 24 24" fill="none" xmlns="http://www.w3.org/2000/svg"> ' )
    ( '<path d="M9.15316 5.40838C10.4198 3.13613 11.0531 2 12 2C12.9469 2 13.5802 3.13612 14.8468 5.40837L15.1745 5.99623C15.5345 6.64193 15.7144 6.96479 15.9951 7.17781C16.2757 7.39083 16.6251 7.4699 17.3241 ' )
    ( '7.62805L17.9605 7.77203C20.4201 8.32856 21.65 8.60682 21.9426 9.54773C22.2352 10.4886 21.3968 11.4691 19.7199 13.4299L19.2861 13.9372C18.8096 14.4944 18.5713 14.773 18.4641 15.1177C18.357 15.4624 18.393 ' )
    ( '15.8341 18.465 16.5776L18.5306 17.2544C18.7841 19.8706 18.9109 21.1787 18.1449 21.7602C17.3788 22.3417 16.2273 21.8115 13.9243 20.7512L13.3285 20.4768C12.6741 20.1755 12.3469 20.0248 12 20.0248C11.6531 ' )
    ( '20.0248 11.3259 20.1755 10.6715 20.4768L10.0757 20.7512C7.77268 21.8115 6.62118 22.3417 5.85515 21.7602C5.08912 21.1787 5.21588 19.8706 5.4694 17.2544L5.53498 16.5776C5.60703 15.8341 5.64305 15.4624 ' )
    ( '5.53586 15.1177C5.42868 14.773 5.19043 14.4944 4.71392 13.9372L4.2801 13.4299C2.60325 11.4691 1.76482 10.4886 2.05742 9.54773C2.35002 8.60682 3.57986 8.32856 6.03954 7.77203L6.67589 7.62805C7.37485 ' )
    ( '7.4699 7.72433 7.39083 8.00494 7.17781C8.28555 6.96479 8.46553 6.64194 8.82547 5.99623L9.15316 5.40838Z" stroke="#1C274C" stroke-width="1.5"/></svg> ' ) ).

    gt_svg_lapse = VALUE #(
    ( '<svg height="65" width="140" xmlns="http://www.w3.org/2000/svg">  ' )
    ( '<circle r="30" cx="33" cy="33" fill="col1" stroke="black" stroke-width="0.5" />  ' )
    ( '<text x="10" y="28" fill="white" font-weight=700 stroke="black" font-size="24">m1</text> ' )
    ( '<circle r="30" cx="80" cy="33" fill="col266" stroke="black" stroke-width="0.5" />  ' )
    ( '<text x="60" y="54" fill="white" font-weight=700 stroke="black" font-size="24">m2</text> ' )
    ( '</svg> ' ) ).

  ENDMETHOD.

  METHOD set_age_color.
    "The age-color grading is derived from the age in days against fibonacci numbers
    TYPES: BEGIN OF lty_colors,
             days  TYPE int2,
             color TYPE c LENGTH 8,
           END OF lty_colors.

    rv_color = '#000000'.
    CHECK NOT iv_date IS INITIAL.
    DATA lt_colorcodes TYPE SORTED TABLE OF lty_colors WITH UNIQUE KEY days.
    lt_colorcodes = VALUE #( ( days = 0 color = '#00ff00' ) ( days = 2 color = '#e6e6ff' ) ( days = 3 color = '#ccccff' )
      ( days = 5 color = '#b3b3ff' ) ( days = 8 color = '#9999ff' ) ( days = 13 color = '#8080ff' ) ( days = 21 color = '#6666ff' )
      ( days = 34 color = '#4d4dff' ) ( days = 55 color = '#3333ff' ) ( days = 89 color = '#1a1aff' ) ( days = 144 color = '#1a1aff' )
      ( days = 233 color = '#0000ff' ) ( days = 377 color = '#0000e6' ) ( days = 610 color = '#0000cc' ) ( days = 987 color = '#0000b3' )
      ( days = 1697 color = '#000099' ) ( days = 2584 color = '#000080' ) ( days = 32000 color = '#000000' ) ).

    DATA(lv_age_in_days) = sy-datum - iv_date.
    LOOP AT lt_colorcodes INTO DATA(ls_colorcode) WHERE days <= lv_age_in_days.
      rv_color = ls_colorcode-color.
    ENDLOOP.

  ENDMETHOD.


  METHOD harvest_counters.
    CLEAR  gs_counters.
    LOOP AT gt_groups INTO DATA(ls_group).
      gs_counters-groups = gs_counters-groups + 1.
      LOOP AT ls_group-objects INTO DATA(ls_object) WHERE object_type <> 'SPACE'.
        gs_counters-objects = gs_counters-objects + 1.
        LOOP AT ls_object-components->gt_components INTO DATA(ls_component).
          CASE ls_component-component_type.
            WHEN 'CLASS'.
              gs_counters-classes = gs_counters-classes + 1.
            WHEN 'METHODS'.
              gs_counters-methods = gs_counters-methods + 1.
            WHEN 'CLASS-METHODS'.
              gs_counters-classmethods = gs_counters-classmethods + 1.
            WHEN 'TABLE'.
              gs_counters-tables = gs_counters-tables + 1.
            WHEN 'REPORT'.
              gs_counters-reports = gs_counters-reports + 1.
            WHEN 'FUNCTION'.
              gs_counters-functions = gs_counters-functions + 1.
          ENDCASE.
        ENDLOOP.
      ENDLOOP.
    ENDLOOP.

  ENDMETHOD.

  METHOD harvest_developmentclasses.
    DATA lv_focus_devclass TYPE devclass.
    LOOP AT gt_groups INTO DATA(ls_group).
      gs_counters-groups = gs_counters-groups + 1.
      LOOP AT ls_group-objects INTO DATA(ls_object).
        gs_counters-objects = gs_counters-objects + 1.
        LOOP AT ls_object-components->gt_components INTO DATA(ls_component).
          READ TABLE lcl_component_documentor=>gt_devclass ASSIGNING FIELD-SYMBOL(<ls_devclass>)
            WITH KEY devclass = ls_component-devclass.
          IF sy-subrc = 0.
            <ls_devclass>-objectcounter = <ls_devclass>-objectcounter + 1.
          ENDIF.
        ENDLOOP.
      ENDLOOP.
    ENDLOOP.

    "Determine relevance: everything with a counter and their parents
    LOOP AT lcl_component_documentor=>gt_devclass ASSIGNING <ls_devclass>
      WHERE objectcounter > 0.
      <ls_devclass>-relevant = abap_true.
      "Find all parents
      lv_focus_devclass = <ls_devclass>-parentcl.
      DO 20 TIMES.
        IF lv_focus_devclass IS INITIAL.
          EXIT.
        ENDIF.
        READ TABLE lcl_component_documentor=>gt_devclass
          ASSIGNING FIELD-SYMBOL(<ls_devclass_parent>)
          WITH KEY devclass = lv_focus_devclass.
        IF sy-subrc = 0.
          <ls_devclass_parent>-relevant = abap_true.
          lv_focus_devclass = <ls_devclass_parent>-parentcl.
        ELSE.
          CLEAR lv_focus_devclass.
        ENDIF.
      ENDDO.
    ENDLOOP.

    DELETE lcl_component_documentor=>gt_devclass WHERE relevant = abap_false.

  ENDMETHOD.

  METHOD print_developmentclass.
    "Recursive calls
    DATA lv_description TYPE string.

    IF iv_devclass-objectcounter = 0.
      APPEND |<tr>| TO gt_html. "No click-link functionality
    ELSE.
      APPEND |<tr class=clickable onclick=INPUT.devclass.value="{ iv_devclass-devclass }";INPUT.submit(); >| TO gt_html.
    ENDIF.
    APPEND |<td style="padding-left:{ ( iv_level * 20 ) }px;"><b>{ iv_devclass-devclass }</b>| TO gt_html.
    lv_description = COND #( WHEN iv_devclass-ctext_N <> '' THEN iv_devclass-ctext_N ELSE iv_devclass-ctext_E ).
    APPEND |</td><td style="">{ lv_description }</td>| TO gt_html.
    if iv_devclass-objectcounter = 0.
      APPEND |<td></td><td</td>| TO gt_html.
    ELSE.
      APPEND |<td style="border:1px solid black;border-radius:5px;text-align:center;">{ iv_devclass-objectcounter } objects</td>| TO gt_html.
      APPEND |<td>.. of { iv_devclass-tadircounter } objects</td>| TO gt_html.
    endif.
    APPEND |</tr>| TO gt_html.

    LOOP AT lcl_component_documentor=>gt_devclass INTO DATA(ls_devclass) USING KEY via_parents
      WHERE parentcl = iv_devclass-devclass.
      print_developmentclass( EXPORTING iv_level = ( iv_level + 1 ) iv_devclass = ls_devclass ).
    ENDLOOP.
  ENDMETHOD.

  METHOD harvest_dates.
    "The components on the group have a CREATED and CHANGED date, which needs to be set with information derived from the components.
    LOOP AT gt_groups ASSIGNING FIELD-SYMBOL(<ls_group>).
      <ls_group>-created = sy-datum.
*      <ls_group>-changed = '19690308'.
      LOOP AT <ls_group>-objects ASSIGNING FIELD-SYMBOL(<ls_object>).
        <ls_object>-created = sy-datum.
*        <ls_object>-changed = '19690308'.
        LOOP AT <ls_object>-components->gt_components INTO DATA(ls_component).
          CASE ls_component-component_type.
            WHEN 'CLASS'.
              <ls_object>-created = COND #( WHEN ls_component-class-createdon < <ls_object>-created THEN ls_component-class-createdon ELSE <ls_object>-created ).
              <ls_object>-changed = COND #( WHEN ls_component-class-changedon > <ls_object>-changed THEN ls_component-class-changedon ELSE <ls_object>-changed ).
            WHEN 'REPORT'.
              <ls_object>-created = COND #( WHEN ls_component-report-cdat < <ls_object>-created THEN ls_component-report-cdat ELSE <ls_object>-created ).
              <ls_object>-changed = COND #( WHEN ls_component-report-udat > <ls_object>-changed THEN ls_component-report-udat ELSE <ls_object>-changed ).
            WHEN 'FUNCTION'.
              <ls_object>-created = COND #( WHEN ls_component-function-created_on < <ls_object>-created THEN ls_component-function-created_on ELSE <ls_object>-created ).
              <ls_object>-changed = COND #( WHEN ls_component-function-created_on > <ls_object>-changed THEN ls_component-function-created_on ELSE <ls_object>-changed ).
            WHEN 'TABLE'.
              <ls_object>-created = COND #( WHEN ls_component-table-created_on < <ls_object>-created THEN ls_component-table-created_on ELSE <ls_object>-created ).
              <ls_object>-changed = COND #( WHEN ls_component-table-changed_on > <ls_object>-changed THEN ls_component-table-changed_on ELSE <ls_object>-changed ).
          ENDCASE.
        ENDLOOP.

        IF NOT <ls_object>-created IS INITIAL.
          <ls_group>-created = COND #( WHEN <ls_object>-created < <ls_group>-created THEN <ls_object>-created ELSE <ls_group>-created ).
        ENDIF.
        IF NOT <ls_object>-changed IS INITIAL.
          <ls_group>-changed = COND #( WHEN <ls_object>-changed > <ls_group>-changed THEN <ls_object>-changed ELSE <ls_group>-changed ).
        ENDIF.
      ENDLOOP.
    ENDLOOP.
  ENDMETHOD.

  METHOD set_abapdoc.

    CHECK lines( it_abapdoc ) > 0.
    APPEND '<div class="comments">' TO gt_html.
    LOOP AT it_abapdoc INTO DATA(ls_abapdocline).
      "@parameter and @exception are ABAPdoc elements that require a bit of special attention
      REPLACE '@parameter' IN ls_abapdocline-content WITH '<p><b>Parameter</b><i>'.
      REPLACE '@exception' IN ls_abapdocline-content WITH '<p><b>Exception</b><i>'.
      REPLACE '|' IN ls_abapdocline-content WITH '</i>'.
      APPEND |{ ls_abapdocline-content }| TO gt_html.
    ENDLOOP.
    APPEND '</div>' TO gt_html.
  ENDMETHOD.

  METHOD mini_dot_as_svg.
    DATA lv_color TYPE c LENGTH 20.
    DATA lv_text TYPE c LENGTH 3.

    IF iv_medium = abap_false.
      rv_colored_dot = gv_svg_mini_icon.
    ELSE.
      rv_colored_dot = gv_svg_mini_icon2. "Just a little bigger
    ENDIF.
    CASE iv_object_type.
      WHEN 'CLASS'.
        lv_color = 'blue'.
        lv_text = 'Cla'.
      WHEN 'TABLE'.
        lv_color = 'orange'.
        lv_text = 'Tab'.
      WHEN 'REPORT'.
        lv_color = 'purple'.
        lv_text = 'Rep'.
      WHEN 'FUNCTION'.
        lv_color = 'red'.
        lv_text = 'Fun'.
      WHEN OTHERS.
        lv_color = 'black'.
        lv_text = '?'.
    ENDCASE.
    REPLACE 'BLACK' IN rv_colored_dot WITH lv_color.
    REPLACE 'TEXT' IN rv_colored_dot WITH lv_text.
  ENDMETHOD.

  METHOD set_group_header.
    DATA lv_colored_dot TYPE char255.
    DATA lt_svg_lapse TYPE STANDARD TABLE OF char255.

    APPEND |<div onclick=document.getElementById("group{ gv_ID }").style.display=(document.getElementById("group{ gv_ID }").style.display=="block")?"none":"block";>| TO gt_html.
    APPEND |<table style="width:100%;"><tr><td style="font-size:30pt;width:60px;font-weight:700;color:lightgray;cursor:pointer;"><br>{ iv_groupnr }.<td>| TO gt_html.
    APPEND |<table style="width:100%;"><tr><td style="width:90%;cursor:pointer;border: 1px solid black;border-radius: 15px;| TO gt_html.
    APPEND |height: 0px;padding-left: 10px;padding-top: 5px;background: linear-gradient(to right,gray,white,white,white,lightgrey);">| TO gt_html.

    LOOP AT is_group-objects INTO DATA(ls_object) WHERE object_type <> 'SPACE'.
      APPEND  mini_dot_as_svg( ls_object-object_type ) TO gt_html.
    ENDLOOP.

    APPEND |</td><td rowspan=2 style="cursor:pointer;">| TO gt_html.

    "Compose an SVG image with a bit of data on it - the create/last change icons
    lt_svg_lapse[] = gt_svg_lapse[].
    LOOP AT lt_svg_lapse ASSIGNING FIELD-SYMBOL(<ls_svg_line>).
      REPLACE 'm1' IN <ls_svg_line> WITH get_date_summary( is_group-created ).
      REPLACE 'col1' IN <ls_svg_line> WITH set_age_color( is_group-created ).
      IF is_group-changed = sy-datum.
        REPLACE 'm2' IN <ls_svg_line> WITH 'Today'.
      ELSE.
        REPLACE 'm2' IN <ls_svg_line> WITH get_date_summary( is_group-changed ).
      ENDIF.
      REPLACE 'col2' IN <ls_svg_line> WITH set_age_color( is_group-changed ).

      APPEND <ls_svg_line> TO gt_html.
    ENDLOOP.

    APPEND |</td></tr>| TO gt_html.
    APPEND |<tr><td style="cursor:pointer;">| TO gt_html.

    APPEND |<h1 style="margin-top:2px;border-bottom:0px solid black;">{ is_group-description }</h1>| TO gt_html.

    APPEND |</td></tr></table>| TO gt_html.

    IF NOT is_group-summary IS INITIAL.
      APPEND |<p>{ is_group-summary }| TO gt_html.
    ENDIF.

    set_all_tagwords( is_group = is_group ).
    APPEND |</td></tr></table></div><hr style="opacity:0.5;">| TO gt_html.

  ENDMETHOD.

  METHOD get_date_summary.
    DATA lv_components TYPE n VALUE 0.

    IF iv_date IS INITIAL.
      rv_result = '.'.
      EXIT.
    ENDIF.
    "Number of days into year, week and day
    DATA(lv_days_total) = sy-datum - iv_date.
    CLEAR rv_result.
    DATA(lv_div) = lv_days_total DIV 365.
    IF ( lv_div > 0 ).
      rv_result = |{ lv_div }j|.
      lv_days_total = lv_days_total - ( lv_div * 365 ).
      lv_components = lv_components + 1.
    ENDIF.
    lv_div = lv_days_total DIV 7.
    IF ( lv_div > 0 ).
      rv_result = |{ rv_result }{ lv_div }w|.
      lv_days_total = lv_days_total - ( lv_div * 7 ).
      lv_components = lv_components + 1.
    ELSEIF lv_components > 0.
      RETURN.
    ENDIF.
    CHECK lv_components < 2.
    IF ( lv_days_total > 0 ).
      rv_result = |{ rv_result }{ lv_days_total }d|.
      lv_components = lv_components + 1.
    ELSEIF lv_components > 0.
      RETURN.
    ENDIF.

  ENDMETHOD.

  METHOD set_all_tagwords.

    DATA lv_all_tagwords TYPE string.
    DATA lt_all_tagwords TYPE STANDARD TABLE OF string.

    CLEAR lv_all_tagwords.
    CLEAR lt_all_tagwords.
    LOOP AT is_group-objects INTO DATA(ls_object) WHERE tagwords <> ''.
      lv_all_tagwords = |{ lv_all_tagwords } { ls_object-tagwords }|.
    ENDLOOP.
    CONDENSE lv_all_tagwords.

    APPEND |<p><span class="comments" style="font-size:12pt;"> | TO gt_html.
    IF NOT lv_all_tagwords IS INITIAL.
      SPLIT lv_all_tagwords AT space INTO TABLE lt_all_tagwords.
      SORT lt_all_tagwords.
      DELETE ADJACENT DUPLICATES FROM lt_all_tagwords.
      lv_all_tagwords = '<b>Tagwords</b> '.
      LOOP AT lt_all_tagwords INTO DATA(lv_tagword).
        lv_all_tagwords = |{ lv_all_tagwords } \| { lv_tagword }|.
        IF strlen( lv_all_tagwords ) > 150.
          APPEND lv_all_tagwords TO gt_html.
          CLEAR lv_all_tagwords.
        ENDIF.
      ENDLOOP.
      APPEND |{ lv_all_tagwords }| TO gt_html.
    ENDIF.
    APPEND '</span>' TO gt_html.
  ENDMETHOD.

  METHOD set_tagwords.
    IF iv_tagwords IS INITIAL.
      APPEND |</td><td style="min-width:150px;">&nbsp;| TO gt_html.
    ELSE.
      APPEND |</td><td style="min-width:150px;"><table><tr><td class=mainLabel style="background-color:darkred;font-size:10pt;">TAGWORDS</td><td style="font-size:10pt;">| TO gt_html.
      SPLIT iv_tagwords AT space INTO TABLE DATA(lt_tokens).
      SORT lt_tokens.
      LOOP AT lt_tokens INTO DATA(lv_token).
        APPEND |{ lv_token }<br>| TO gt_html.
      ENDLOOP.
      APPEND |</td></tr></table>| TO gt_html.
    ENDIF.
  ENDMETHOD.

  METHOD set_parameter_svg.

    CASE iv_parameter_type.
      WHEN 0.
        APPEND LINES OF gt_svg_exporting TO gt_html.
      WHEN 1.
        APPEND LINES OF gt_svg_importing TO gt_html.
      WHEN 2.
        APPEND LINES OF gt_svg_changing TO gt_html.
      WHEN 3.
        APPEND LINES OF gt_svg_returning TO gt_html.

      WHEN 6.
        APPEND LINES OF gt_svg_parameter TO gt_html.
      WHEN 7.
        APPEND LINES OF gt_svg_selectoption TO gt_html.

      WHEN 9.
        APPEND LINES OF gt_svg_exception TO gt_html.
    ENDCASE.

  ENDMETHOD.

  METHOD set_links.

    CHECK lines( is_object-links ) > 0.
    APPEND '<h3 style="margin-left:40px;">External links</h3>' TO gt_html.
    LOOP AT is_object-links INTO DATA(ls_link).
      APPEND |<p style="margin-left:90px;"><a href="{ ls_link-link }" target="new">{ ls_link-label }</a>| TO gt_html.
    ENDLOOP.
    APPEND '<p>&nbsp;' TO gt_html.
  ENDMETHOD.

  METHOD set_reviews.

    CHECK lines( is_object-reviews ) > 0.
    APPEND '<h3 style="margin-left:40px;">Reviews</h3>' TO gt_html.
    LOOP AT is_object-reviews INTO DATA(ls_review).
      APPEND |<section>| TO gt_html.
      APPEND |<p>| TO gt_html. " style="margin-left:90px;"
      DO 5 TIMES.
        IF sy-index <= ls_review-rating.
          APPEND LINES OF gt_svg_star TO gt_html.
        ELSE.
          APPEND LINES OF gt_svg_star_empty TO gt_html.
        ENDIF.
      ENDDO.
      APPEND |<b>{ ls_review-summary }</b><br>| TO gt_html.
      string_to_html( ls_review-remarks ).
      APPEND |<br><span style="font-size:9pt;">{ ls_review-date DATE = USER } \| { ls_review-uname }| TO gt_html.
      APPEND | { lcl_component_documentor=>get_username( ls_review-uname ) } { ls_review-username } </span>| TO gt_html.
      APPEND '</section>' TO gt_html.
    ENDLOOP.
  ENDMETHOD.

  METHOD set_object_header.
    DATA lt_svg_lapse TYPE STANDARD TABLE OF char255.
    DATA lv_review_date TYPE d.
    DATA lv_review_text TYPE string.

    gv_id = gv_id + 1.
    APPEND |<div class=object><table><tr>| TO gt_html.
    APPEND |<td style="min-width:180px;cursor:pointer;" onclick=navigator.clipboard.writeText("{ is_object-object_name }");window.prompt(decodeURI("Copied%20to%20Clipboard%20..."),"{ is_object-object_name }");>| TO gt_html.
    CASE is_object-object_type.
      WHEN 'CLASS'.
        APPEND LINES OF gt_svg_class TO gt_html.
      WHEN 'REPORT'.
        APPEND LINES OF gt_svg_report TO gt_html.
      WHEN 'TABLE'.
        APPEND LINES OF gt_svg_table TO gt_html.
      WHEN 'FUNCTION'.
        APPEND LINES OF gt_svg_function TO gt_html.
    ENDCASE.
    APPEND |</td><td onclick=document.getElementById("section{ gv_ID }").style.display=(document.getElementById("section{ gv_ID }").style.display=="block")?"none":"block"; | TO gt_html.
    APPEND |class=leftPanel style="width:600px;cursor:pointer;"><table><tr><td><h2>{ is_object-object_name }</h2></td>| TO gt_html.

    CLEAR: lv_review_text, lv_review_date.
    IF lines( is_object-reviews ) > 0.
      LOOP AT is_object-reviews INTO DATA(ls_review).
        IF ls_review-date > lv_review_date.
          lv_review_date =  ls_review-date.
        ENDIF.
      ENDLOOP.
      lv_review_text = |{ lines( is_object-reviews ) } reviews - { get_date_summary( ls_review-date ) }|.
    ENDIF.
    APPEND |<td style="min-width:50px;text-align:right;" title="{ lv_review_text }">| TO gt_html.
    IF NOT lv_review_text IS INITIAL.
      APPEND LINES OF gt_svg_star TO gt_html.
    ENDIF.
    APPEND |</td></tr></table>| TO gt_html.

    READ TABLE is_object-components->gt_components INTO DATA(ls_main_component)
      WITH KEY component_type = is_object-object_type component_name = is_object-object_name.
    IF sy-subrc = 0.
      APPEND |<b>{ ls_main_component-description }</b>| TO gt_html.
      set_abapdoc( ls_main_component-abapdoc ).

      APPEND |</td><td style="cursor:pointer;" onclick=document.getElementById("section{ gv_ID }").style.display=(document.getElementById("section{ gv_ID }").style.display=="block")?"none":"block";>| TO gt_html.
      "Compose an SVG image with a bit of data on it - the create/last change icons
      lt_svg_lapse[] = gt_svg_lapse[].
      LOOP AT lt_svg_lapse ASSIGNING FIELD-SYMBOL(<ls_svg_line>).
        REPLACE 'm1' IN <ls_svg_line> WITH get_date_summary( is_object-created ).
        REPLACE 'col1' IN <ls_svg_line> WITH set_age_color( is_object-created ).
        IF is_object-changed = sy-datum.
          REPLACE 'm2' IN <ls_svg_line> WITH 'Today'.
        ELSE.
          REPLACE 'm2' IN <ls_svg_line> WITH get_date_summary( is_object-changed ).
        ENDIF.
        REPLACE 'col2' IN <ls_svg_line> WITH set_age_color( is_object-changed ).

        APPEND <ls_svg_line> TO gt_html.
      ENDLOOP.

      set_tagwords( is_object-tagwords ).
    ELSE.
      APPEND |<h4 style="color:red;"><span style="font-size:18pt;">Sorry !</span> { is_object-object_type CASE = LOWER } not found</h4>| TO gt_html.
    ENDIF.
    APPEND |</td></tr></table>| TO gt_html.
    APPEND |<div id="section{ gv_ID }" style="display:none;"><table><tr><td class="leadColumn"></td><td> | TO gt_html.

  ENDMETHOD.

  METHOD set_group_detail.
    DATA lv_value TYPE char120.
    APPEND |<table class="techDetail"><tr><td rowspan=20 style="vertical-align:middle;">| TO gt_html.
    APPEND LINES OF gt_svg_screw TO gt_html.
    APPEND |</td><td class="label">Created by</td><td>{ iv_created_by } { lcl_component_documentor=>get_username( iv_created_by ) }</td>|  TO gt_html.
    APPEND |<td class="label"> on</td><td> { iv_created_on DATE = USER } { get_date_summary( iv_created_on ) }</td>| TO gt_html.
    APPEND |<td rowspan=20 style="vertical-align:middle;text-align:right;">| TO gt_html.
    APPEND LINES OF gt_svg_screw TO gt_html.
    APPEND |</td></tr>| TO gt_html.

    LOOP AT it_content INTO DATA(ls_content).
      lv_value = ls_content-value. "Solution to the problem: how to check whether a string is empty
      IF NOT ( ls_content-username IS INITIAL AND ls_content-datevalue IS INITIAL ).
        APPEND |<tr><td class="label">{ ls_content-label }</td><td> { ls_content-username } { lcl_component_documentor=>get_username(  ls_content-username ) }</td>| TO gt_html.
        APPEND |<td class="label"> on</td><td> { ls_content-datevalue DATE = USER } { get_date_summary( ls_content-datevalue ) }</td></tr>| TO gt_html.
      ELSEIF NOT lv_value IS INITIAL.
        APPEND |<tr><td class="label">{ ls_content-label }</td><td colspan=3> { ls_content-value }</td></tr>| TO gt_html.
      ENDIF.
    ENDLOOP.
    APPEND '</table><p>' TO gt_html.

  ENDMETHOD.

  METHOD filter_focus.

    DATA lr_main_object_types TYPE RANGE OF char10.
    DATA lv_inherited_devclass TYPE devclass.

    CHECK NOT iv_devclass IS INITIAL.
    lr_main_object_types = VALUE #( ( sign = 'I' option = 'EQ' low = 'CLASS' ) ( sign = 'I' option = 'EQ' low = 'REPORT' )
      ( sign = 'I' option = 'EQ' low = 'TABLE' ) ( sign = 'I' option = 'EQ' low = 'FUNCTION' ) ).
    LOOP AT gt_groups ASSIGNING FIELD-SYMBOL(<ls_group>).
      LOOP AT <ls_group>-objects ASSIGNING FIELD-SYMBOL(<ls_object>)
        WHERE object_type IN lr_main_object_types.

        CLEAR lv_inherited_devclass.
        LOOP AT <ls_object>-components->gt_components INTO DATA(ls_component).
          lv_inherited_devclass = COND #(
            WHEN ls_component-devclass = '' THEN lv_inherited_devclass ELSE ls_component-devclass ).
          IF lv_inherited_devclass <> iv_devclass.
            DELETE <ls_object>-components->gt_components.
          ENDIF.
        ENDLOOP.
        IF lines( <ls_object>-components->gt_components ) = 0.
          DELETE <ls_group>-objects.
        ENDIF.
      ENDLOOP.
      "Are the objects that are still listed all SPACE ?
      LOOP AT <ls_group>-objects TRANSPORTING NO FIELDS WHERE object_type <> 'SPACE'.
      ENDLOOP.
      IF sy-subrc <> 0.
        DELETE gt_groups.
      ENDIF.
    ENDLOOP.

  ENDMETHOD.

  METHOD zone_reporter.
    DATA lv_component_name TYPE char255.
    DATA lv_tab TYPE char20.

    set_html_style(  ).
    set_svg_images(  ).
    gv_ID = 1000.

    APPEND |<form name="INPUT" method="get" action="SAPEVENT:INPUT">| TO gt_html.
    APPEND |<input type="hidden" name="devclass" value="none" />| TO gt_html.
    APPEND |</form>| TO gt_html.

    APPEND |<table style="width:100%"><tr><td style="width:40%;text-align:center;vertical-align:middle;">| TO gt_html.
    APPEND |<img src={ gs_images-logo }></td>| TO gt_html.
    APPEND |<td style="padding-right:60px;">| TO gt_html.
    APPEND LINES OF gt_documentheader TO gt_html.
    APPEND |</td></tr></table><br><br>| TO gt_html.

    harvest_counters(  ).
    APPEND |<span style="font-size:smaller;">{ lcl_component_documentor=>get_zone_version(  ) }</span>| TO gt_html.
    APPEND |<table class=countsummary><tr><td>{ gs_counters-groups } topics \| </td><td>| TO gt_html.
    APPEND mini_dot_as_svg( iv_object_type = 'CLASS' iv_medium = abap_true ) TO gt_html.
    APPEND |</td><td>{ gs_counters-classes } classes \| </td><td>| TO gt_html.
    IF gs_counters-classmethods > 0.
      APPEND |<i>{ gs_counters-classmethods } class-methods \| </i>| TO gt_html.
    ENDIF.
    IF gs_counters-methods > 0.
      APPEND |<i>{ gs_counters-methods } methods \| </i>| TO gt_html.
    ENDIF.
    APPEND '</td><td>' TO gt_html.
    IF gs_counters-reports > 0.
      APPEND mini_dot_as_svg( iv_object_type = 'REPORT'  iv_medium = abap_true ) TO gt_html.
      APPEND |</td><td>{ gs_counters-reports } reports \| </td><td>| TO gt_html.
    ENDIF.
    IF gs_counters-tables > 0.
      APPEND mini_dot_as_svg( iv_object_type = 'TABLE'  iv_medium = abap_true ) TO gt_html.
      APPEND |</td><td>{ gs_counters-tables } tables \| </td><td>| TO gt_html.
    ENDIF.
    IF gs_counters-functions > 0.
      APPEND mini_dot_as_svg( iv_object_type = 'FUNCTION' iv_medium = abap_true ) TO gt_html.
      APPEND |</td><td>{ gs_counters-functions } functions \| </td><td>| TO gt_html.
    ENDIF.
    APPEND |{ gs_counters-objects } total </td></tr></table> | TO gt_html.

    harvest_developmentclasses(  ).
    APPEND |<h2 style="width:100%;">Overview development classes</h2><p><table style="width:80%;"> | TO gt_html.
    LOOP AT lcl_component_documentor=>gt_devclass INTO DATA(ls_devclass)
      USING KEY via_parents WHERE parentcl = ''.
      print_developmentclass( iv_level = 1 iv_devclass = ls_devclass ).
    ENDLOOP.
    APPEND |</table> | TO gt_html.

    APPEND |<h2 style="width:100%;">Overview chapters</h2> | TO gt_html.
    harvest_dates(  ).

    LOOP AT gt_groups INTO DATA(ls_group).
      DATA(lv_groupnr) = sy-tabix.
      gv_ID = gv_ID + 1.

      set_group_header( iv_groupnr = lv_groupnr is_group = ls_group ).
      APPEND |<section><div id=group{ gv_ID } style="display:none;">| TO gt_html.

      LOOP AT ls_group-objects INTO DATA(ls_object).

        IF 'CLASS:REPORT:TABLE:FUNCTION' CS ls_object-object_type.
          set_object_header( ls_object ).
        ENDIF.

        CASE ls_object-object_type.
* ====================================================================================================
          WHEN 'CLASS'.
* ====================================================================================================

            READ TABLE ls_object-components->gt_components INTO DATA(ls_component)
              WITH KEY component_type = ls_object-object_type component_name = ls_object-object_name.

            set_group_detail( iv_created_by = ls_component-class-author iv_created_on = ls_component-class-createdon
              it_content = VALUE #(
                ( label = 'Last changed by' username = ls_component-class-changedby datevalue = ls_component-class-changedon )
                ( label = 'Abap coding' value = |{ ls_component-class-linecount  } lines in { ls_component-class-methods } methods | &&
                  |{ COND string( WHEN ls_component-class-redefinitions = 0 THEN '' ELSE |{ ls_component-class-redefinitions } redefinitions| ) } | )
                ( label = 'Message' value = |{ ls_component-class-message } | )
                ( label = 'Superclass' value = |{ ls_component-class-superclass }| )
                ( label = 'Interfaces' value = |{ ls_component-class-interfaces }| )
                ( label = 'Development class' value = |{ ls_component-devclass } { ls_component-devclass_text }| ) ) ).

            set_reviews( ls_object ).
            set_links( ls_object ).

            IF lines( ls_object-components->gt_components ) > 1.
              APPEND '<h3 style="margin-left:40px;">Components</h3>' TO gt_html.
            ENDIF.

            DATA(lv_filter_on_methods) = ls_component-class-filter_on_methods.

            "Constants
            READ TABLE ls_object-components->gt_components WITH KEY component_type = 'CONSTANTS' TRANSPORTING NO FIELDS.
            IF sy-subrc = 0.
              DATA lv_constants_value TYPE string.
              APPEND |<table><tr><td class=mainLabel style="background-color:#ff9900;">CONSTANTS</td><td>| TO gt_html.
              LOOP AT ls_object-components->gt_components INTO ls_component
                WHERE component_type = 'CONSTANTS'.

                lv_constants_value = COND #( WHEN ls_component-attvalue = '' THEN '...' ELSE |= <b>{ ls_component-attvalue }</b>|  ).
                lv_tab =  COND #( WHEN ls_component-attvalue = '' THEN '' ELSE '&nbsp;&nbsp;&nbsp;'  ).

                lv_component_name = |<span onclick=navigator.clipboard.writeText("{ ls_component-component_name }");| &&
                   |window.prompt(decodeURI("Copied%20to%20Clipboard%20..."),"{ ls_component-component_name }");>|.

                IF lines( ls_component-abapdoc ) > 0.
                  APPEND |<p style="margin-top:10px;">| TO gt_html.
                  set_abapdoc( ls_component-abapdoc ).
                  APPEND |{ lv_tab }<code class=clickable style="margin-left:10px;" >| TO gt_html.
                ELSE.
                  APPEND |<p>{ lv_tab }<code class=clickable>| TO gt_html.
                ENDIF.
                APPEND lv_component_name TO gt_html.
                APPEND |{ ls_component-component_name }</span></code>{ lv_constants_value }</p>| TO gt_html.
              ENDLOOP.
              APPEND |</td></tr></table>| TO gt_html.
            ENDIF.

            "Class-data
            READ TABLE ls_object-components->gt_components WITH KEY component_type = 'CLASS-DATA' TRANSPORTING NO FIELDS.
            IF sy-subrc = 0.
              APPEND |<table><tr><td class=mainLabel style="background-color:darkblue;">CLASS-DATA</td><td>| TO gt_html.
              LOOP AT ls_object-components->gt_components INTO ls_component
                WHERE component_type = 'CLASS-DATA'.
                DATA(lv_readonly) = COND string( WHEN ls_component-read_only = abap_true THEN '<span class=readonly>(read only)</span>' ELSE '' ).

                lv_component_name = |onclick=navigator.clipboard.writeText("{ ls_component-component_name }");| &&
                 |window.prompt(decodeURI("Copied%20to%20Clipboard%20..."),"{ ls_component-component_name }");>|.

                IF lines( ls_component-abapdoc ) > 0.
                  APPEND |<p style="margin-top:10px;">| TO gt_html.
                  set_abapdoc( ls_component-abapdoc ).
                  APPEND |<code class=clickable style="margin-left:10px;" | TO gt_html.
                ELSE.
                  APPEND |<p><code class=clickable style="margin-left:10px;" | TO gt_html.
                ENDIF.
                APPEND lv_component_name TO gt_html.
                APPEND |{ ls_component-component_name }</code>{ lv_readonly }</p>| TO gt_html.
              ENDLOOP.
              APPEND |</td></tr></table>| TO gt_html.
            ENDIF.

            "Instance data
            READ TABLE ls_object-components->gt_components WITH KEY component_type = 'DATA' TRANSPORTING NO FIELDS.
            IF sy-subrc = 0.
              APPEND |<table><tr><td class=mainLabel style="background-color:blue;">DATA</td><td>| TO gt_html.
              LOOP AT ls_object-components->gt_components INTO ls_component
                WHERE component_type = 'DATA'.
                lv_readonly = COND string( WHEN ls_component-read_only = abap_true THEN '<span class=readonly>(read only)</span>' ELSE '' ).

                lv_component_name = |onclick=navigator.clipboard.writeText("{ ls_component-component_name }");| &&
                 |window.prompt(decodeURI("Copied%20to%20Clipboard%20..."),"{ ls_component-component_name }");>|.

                IF lines( ls_component-abapdoc ) > 0.
                  APPEND |<p style="margin-top:10px;">| TO gt_html.
                  set_abapdoc( ls_component-abapdoc ).
                  APPEND |<code style="cursor:pointer;margin-left:10px;" | TO gt_html.
                  APPEND |<code class=clickable style="margin-left:10px;" | TO gt_html.
                ELSE.
                  APPEND |<p><code class=clickable style="margin-left:10px;" | TO gt_html.
                ENDIF.
                APPEND lv_component_name TO gt_html.
                APPEND |{ ls_component-component_name }</code>{ lv_readonly }</p>| TO gt_html.
              ENDLOOP.
              APPEND |</td></tr></table>| TO gt_html.
            ENDIF.

            "Class-Methodes
            LOOP AT ls_object-components->gt_components INTO ls_component
              WHERE component_type = 'CLASS-METHODS'.

              APPEND |<table><tr><td class=mainLabel style="background-color:darkblue;" rowspan=3>CLASS-METHOD</td><td class=componentTitle>| TO gt_html.
              APPEND |<span class=clickable onclick=navigator.clipboard.writeText("{ ls_component-component_name }");| &&
                     |window.prompt(decodeURI("Copied%20to%20Clipboard%20..."),"{ ls_component-component_name }");>| TO gt_html.
              APPEND |{ ls_component-component_name }</span>| TO gt_html.
              IF ls_component-redefinition = abap_true.
                APPEND |<span class=hitcount>Redefinition</span>| TO gt_html.
              ENDIF.
              IF ls_component-method_hitcount = 1.
                APPEND |<span class=hitcount>(used from 1 location)</span>| TO gt_html.
              ELSEIF ls_component-method_hitcount > 1.
                APPEND |<span class=hitcount>(used from { ls_component-method_hitcount } locations)</span>| TO gt_html.
              ENDIF.
              APPEND |</td><td rowspan=2>| TO gt_html.
              APPEND |<table><tr><td class=parameterLabel>PARAMETERS</td><td><table>| TO gt_html.
              LOOP AT ls_component-parameters INTO DATA(ls_parameter).
                APPEND '<tr><td>' TO gt_html.
                set_parameter_svg( ls_parameter-pardecltyp ).
                APPEND |</td><td class=parameterListing>{ ls_parameter-parameter }</td></tr>| TO gt_html.
              ENDLOOP.
              IF sy-subrc <> 0.
                APPEND '<tr><td></td></tr>' TO gt_html.
              ENDIF.
              APPEND '</table></td></tr></table> </td></tr>' TO gt_html.

              APPEND |<tr><td>| TO gt_html.
              set_abapdoc( ls_component-abapdoc ).
              APPEND '</td></tr></table>' TO gt_html.
            ENDLOOP.

            "Instance methods
            LOOP AT ls_object-components->gt_components INTO ls_component
              WHERE component_type = 'METHODS'.
              APPEND |<table><tr><td class=mainLabel style="background-color:blue;" rowspan=3>METHOD</td><td class=componentTitle>| TO gt_html.
              APPEND |<span class=clickable onclick=navigator.clipboard.writeText("{ ls_component-component_name }");| &&
                     |window.prompt(decodeURI("Copied%20to%20Clipboard%20..."),"{ ls_component-component_name }");>| TO gt_html.
              APPEND |{ ls_component-component_name }</span>| TO gt_html.

              IF ls_component-redefinition = abap_true.
                APPEND |<span class=hitcount>Redefinition</span>| TO gt_html.
              ENDIF.
              IF ls_component-method_hitcount = 1.
                APPEND |<span class=hitcount>(used from 1 location)</span>| TO gt_html.
              ELSEIF ls_component-method_hitcount > 1.
                APPEND |<span class=hitcount>(used from { ls_component-method_hitcount } locations)</span>| TO gt_html.
              ENDIF.
              APPEND |</td><td rowspan=2><table><tr><td class=parameterLabel>PARAMETERS</td><td><table>| TO gt_html.
              LOOP AT ls_component-parameters INTO ls_parameter.
                APPEND '<tr><td>' TO gt_html.
                set_parameter_svg( ls_parameter-pardecltyp ).
                APPEND |</td><td class=parameterListing>{ ls_parameter-parameter }</td></tr>| TO gt_html.
              ENDLOOP.
              IF sy-subrc <> 0.
                APPEND '<tr><td></td></tr>' TO gt_html.
              ENDIF.
              APPEND '</table></td></tr></table> </td></tr>' TO gt_html.
              APPEND |<tr><td>| TO gt_html.
              set_abapdoc( ls_component-abapdoc ).
              APPEND '</td></tr></table>' TO gt_html.
            ENDLOOP.

            "A warning on method-filtering.
            IF lv_FILTER_ON_METHODS = abap_true.
              APPEND '<p><br><b>Note: not all available PUBLIC methods are displayed (filtering)</b>' TO gt_html.
            ENDIF.
            APPEND '</td></tr></table></div></div>' TO gt_html.

* ====================================================================================================
          WHEN 'REPORT'.
* ====================================================================================================

            READ TABLE ls_object-components->gt_components INTO ls_component
              WITH KEY component_type = ls_object-object_type component_name = ls_object-object_name.

            DATA lt_group_detail_content TYPE gty_content_tt.
            DATA lv_count_text TYPE string.
            lv_count_text = COND #( WHEN lines( ls_component-report-includes ) = 0 THEN '' ELSE ' (with includes)' ).
            lt_group_detail_content = VALUE #(
                ( label = 'Last changed by' username = ls_component-report-unam datevalue = ls_component-report-udat )
                ( label = 'Lines of Abap coding' value = |{ ls_component-report-linecount } { lv_count_text }| )
                ( label = 'Development class' value = |{ ls_component-devclass } { ls_component-devclass_text }| ) ).
            LOOP AT ls_component-report-includes INTO DATA(lv_include).
              APPEND VALUE #( label = 'Include' value = lv_include ) TO lt_group_detail_content.
            ENDLOOP.

            SELECT SINGLE tstct~tcode, tstct~ttext FROM tstc
              INNER JOIN tstct ON tstct~tcode = tstc~tcode
              INTO (@DATA(lv_tcode), @DATA(lv_ttext))
              WHERE pgmna = @ls_object-object_name AND tstct~sprsl = @sy-langu.
            IF sy-subrc <> 0.
              SELECT SINGLE tstct~tcode, tstct~ttext FROM tstc
                INNER JOIN tstct ON tstct~tcode = tstc~tcode
                INTO (@lv_tcode, @lv_ttext)
                WHERE pgmna = @ls_object-object_name AND tstct~sprsl = 'E'.
            ENDIF.
            IF sy-subrc = 0.
              APPEND VALUE #( label = 'Transaction' value = |{ lv_tcode } { lv_ttext }| ) TO lt_group_detail_content.
            ENDIF.

            set_group_detail(
              iv_created_by = ls_component-report-cnam
              iv_created_on = ls_component-report-cdat
              it_content = lt_group_detail_content ).

            set_reviews( ls_object ).
            set_links( ls_object ).

            APPEND |<td><table style="margin-left:90px;"><tr><td class=parameterLabel>PARAMETERS</td><td><table>| TO gt_html.
            READ TABLE ls_object-components->gt_components INTO ls_component INDEX 1.
            LOOP AT ls_component-parameters INTO ls_parameter.
              IF sy-tabix > 8.
                APPEND |<tr><td></td><td>{ lines( ls_component-parameters ) - 8 } more ...</td></tr>| TO gt_html.
                EXIT.
              ENDIF.
              APPEND |<tr><td>| TO gt_html.
              set_parameter_svg( ls_parameter-pardecltyp ).
              APPEND |</td><td style="vertical-align:middle;">{ ls_parameter-parameter }</td></tr>| TO gt_html.
            ENDLOOP.
            IF sy-subrc <> 0.
              APPEND '<tr><td></td></tr>' TO gt_html.
            ENDIF.
            APPEND '</table></td></tr></table></td></tr>' TO gt_html.
            APPEND '</table></div></div>' TO gt_html.

* ====================================================================================================
          WHEN 'TABLE'.
* ====================================================================================================

            READ TABLE ls_object-components->gt_components INTO ls_component
              WITH KEY component_type = ls_object-object_type component_name = ls_object-object_name.

            set_group_detail( iv_created_by = ls_component-table-created_by iv_created_on = ls_component-table-created_on
              it_content = VALUE #(
                ( label = 'Last changed by' username = ls_component-table-changed_by datevalue = ls_component-table-changed_on )
                ( label = 'Has table maintenance' value = |{ COND #( WHEN ls_component-table-maintenance = abap_true THEN 'Yes' ELSE 'No' ) }|  )
                ( label = 'Development class' value = |{ ls_component-devclass } { ls_component-devclass_text }| ) ) ).

            set_reviews( ls_object ).
            set_links( ls_object ).
            APPEND '<h3 style="margin-left:40px;">Definition</h3>' TO gt_html.
            APPEND '</table><table class=bordered><tr class=header><td>Fieldname</td><td>Type</td><td>Description</td></tr>' TO gt_html.

            DATA lv_fields TYPE string.
            DATA lv_fieldname TYPE string.
            DATA lv_html_line TYPE string.
            DATA lv_description TYPE string.
            DATA lv_type TYPE char40.
            CLEAR lv_fields.
            LOOP AT ls_component-table-dd03l INTO DATA(ls_dd03l) WHERE fieldname(5) <> '.INCL'.
* Field description and type definition:
              lv_fieldname = |{ ls_object-object_name }-{ ls_dd03l-fieldname }|.
              lv_description = lcl_component_documentor=>get_sap_description( fieldreference = lv_fieldname ).
              WRITE: ls_dd03l-leng TO lv_type NO-ZERO LEFT-JUSTIFIED.
              SHIFT lv_type RIGHT BY 1 PLACES.
              lv_type(1) = ls_dd03l-inttype.
              lv_type = |{ lv_type }|.
              CONDENSE lv_type NO-GAPS.
* Field (or key field)
              lv_html_line = COND #( WHEN ls_dd03l-keyflag = abap_true THEN |<u><b>{ ls_dd03l-fieldname }</b></u>| ELSE |{ ls_dd03l-fieldname }| ).
              APPEND  |<tr><td>{ lv_html_line }</td><td>{ lv_type }</td><td>{ lv_description }</td></tr>| TO gt_html.
              lv_fields = lv_fields + 1.
              IF lv_fields > 50.
                APPEND |<tr><td colspan=3>Only 50 fields listed</td></tr>| TO gt_html.
                EXIT.
              ENDIF.
            ENDLOOP.
            APPEND '</table></div></div>' TO gt_html.

* ====================================================================================================
          WHEN 'FUNCTION'.
* ====================================================================================================

            READ TABLE ls_object-components->gt_components INTO ls_component
              WITH KEY component_type = ls_object-object_type component_name = ls_object-object_name.

            set_group_detail( iv_created_by = ls_component-function-author iv_created_on = ls_component-function-created_on
              it_content = VALUE #(
                ( label = 'Area' value = ls_component-function-area )
                ( label = 'Where-used: used from' value = |{ ls_component-function-hitcount } locations| )
                ( label = 'Lines of Abap coding' value = ls_component-function-linecount  )
                ( label = 'Development class' value = |{ ls_component-devclass } { ls_component-devclass_text }| ) ) ).

            set_reviews( ls_object ).
            set_links( ls_object ).

            APPEND |</td><td rowspan=2><table><tr><td class=parameterLabel>PARAMETERS</td><td><table>| TO gt_html.
            LOOP AT ls_component-parameters INTO ls_parameter.
              APPEND '<tr><td>' TO gt_html.
              set_parameter_svg( ls_parameter-pardecltyp ).
              APPEND |</td><td style="vertical-align:middle;">{ ls_parameter-parameter }</td></tr>| TO gt_html.
            ENDLOOP.
            IF sy-subrc <> 0.
              APPEND '<tr><td></td></tr>' TO gt_html.
            ENDIF.
            APPEND '</table></td></tr></table> </td></tr>' TO gt_html.
            APPEND '</table></div></div>' TO gt_html.

* ====================================================================================================
          WHEN 'SPACE'.
* ====================================================================================================
            "A bit of space on the overview
            APPEND '<br><br><br>' TO gt_html.

        ENDCASE.

      ENDLOOP.

      APPEND '<br><br><br></section></div>' TO gt_html.
    ENDLOOP.
    APPEND |<p><br><center><span class=version>{ sy-datum DATE = USER } on SAP { sy-sysid } report/transaction { sy-repid }</span></center>| TO gt_html.
    APPEND '</body></html>' TO gt_html.

  ENDMETHOD.

ENDCLASS.

PARAMETERS pa_devcl TYPE devclass NO-DISPLAY.

START-OF-SELECTION.


  CALL FUNCTION 'SAPGUI_PROGRESS_INDICATOR'
    EXPORTING
      percentage = 0
      text       = 'Starting up and gathering information...'.

  DATA(go_documentation) = NEW lcl_document_groups( ).
* ====================================================================================================
  INCLUDE zone_script.
* ====================================================================================================
  "Apply development class filter - when applicable
  go_documentation->filter_focus( pa_devcl ).

  "Fetch the development class hierarchy - custom classes only
  lcl_component_documentor=>read_developmentclasses(  ).

  go_documentation->zone_reporter(  ).

  CALL FUNCTION 'SAPGUI_PROGRESS_INDICATOR'
    EXPORTING
      percentage = 0
      text       = 'Enjoy...'.

  CALL SCREEN 900.

MODULE status_0900 OUTPUT.
  SET PF-STATUS 'MAIN'.
  SET TITLEBAR '001'.

  IF go_documentation->go_container IS INITIAL.
    CREATE OBJECT go_documentation->go_container
      EXPORTING
        container_name = 'CUSTOM_CONTROL'
      EXCEPTIONS
        OTHERS         = 4.
    CREATE OBJECT go_documentation->go_html_control
      EXPORTING
        parent = go_documentation->go_container.

    "To enable response from the HTML document
    go_documentation->gt_myevents = VALUE #(
      ( eventid = go_documentation->go_html_control->m_id_sapevent
        appl_event = 'x' ) ).
    CALL METHOD go_documentation->go_html_control->set_registered_events
      EXPORTING
        events = go_documentation->gt_myevents.
    CREATE OBJECT go_documentation->go_event_receiver.
    SET HANDLER go_documentation->go_event_receiver->handle_sapevent
                FOR go_documentation->go_html_control.

    "Load the html control with the (already prepared) html/javascript content
    go_documentation->go_html_control->load_data(
      IMPORTING assigned_url = go_documentation->gv_url
      CHANGING data_table = go_documentation->gt_html ).
  ENDIF.
  go_documentation->go_html_control->show_url(
    EXPORTING url = go_documentation->gv_url ).

ENDMODULE.

MODULE user_command_0900 INPUT.
  CASE gv_okcode.
    WHEN  'BACK' OR 'LEAVE'.
      LEAVE PROGRAM.
    WHEN 'DOWNLOAD'.
      DATA lv_returncode TYPE sy-subrc.
      cl_gui_frontend_services=>clipboard_export(
        IMPORTING data = go_documentation->gt_html
        CHANGING   rc = lv_returncode
        EXCEPTIONS OTHERS = 4 ).
      IF sy-subrc = 0 AND lv_returncode = 0.
        MESSAGE 'Full HTML content placed on clipboard' TYPE 'S'.
      ENDIF.
  ENDCASE.
ENDMODULE.